pkgs/by-name/ca/caprine-bin/build-from-appimage.nix

   1 {
   2   fetchurl,
   3   appimageTools,
   4   xorg,
   5   pname,
   6   version,
   7   sha256,
   8   metaCommon ? { },
   9 }:
  10
  11 let
  12   src = fetchurl {
  13     url = "https://github.com/sindresorhus/caprine/releases/download/v${version}/Caprine-${version}.AppImage";
  14     name = "Caprine-${version}.AppImage";
  15     inherit sha256;
  16   };
  17   extracted = appimageTools.extractType2 { inherit pname version src; };
  18 in
  19 (appimageTools.wrapType2 {
  20   inherit pname version src;
  21
  22   passthru = {
  23     inherit pname version src;
  24   };
  25
  26   profile = ''
  27     export LC_ALL=C.UTF-8
  28   '';
  29
  30   extraInstallCommands = ''
  31     mkdir -p $out/share
  32     "${xorg.lndir}/bin/lndir" -silent "${extracted}/usr/share" "$out/share"
  33     ln -s ${extracted}/caprine.png $out/share/icons/caprine.png
  34     mkdir $out/share/applications
  35     cp ${extracted}/caprine.desktop $out/share/applications/
  36     substituteInPlace $out/share/applications/caprine.desktop \
  37         --replace AppRun caprine
  38   '';
  39
  40   meta = metaCommon // {
  41     platforms = [ "x86_64-linux" ];
  42   };
  43 })