pkgs/by-name/ca/cardinal/package.nix

   1 {
   2   stdenv,
   3   fetchurl,
   4   cmake,
   5   dbus,
   6   fftwFloat,
   7   file,
   8   freetype,
   9   jansson,
  10   lib,
  11   libGL,
  12   libX11,
  13   libXcursor,
  14   libXext,
  15   libXrandr,
  16   libarchive,
  17   libjack2,
  18   liblo,
  19   libsamplerate,
  20   libsndfile,
  21   makeWrapper,
  22   pkg-config,
  23   python3,
  24   speexdsp,
  25   libglvnd,
  26   headless ? false,
  27 }:
  28
  29 stdenv.mkDerivation rec {
  30   pname = "cardinal";
  31   version = "24.09";
  32
  33   src = fetchurl {
  34     url = "https://github.com/DISTRHO/Cardinal/releases/download/${version}/cardinal+deps-${version}.tar.xz";
  35     hash = "sha256-vJxKtZ0rVjf0RJfTNRxpzps1F2k0hHuiPnd1OwpULhQ=";
  36   };
  37
  38   prePatch = ''
  39     patchShebangs ./dpf/utils/generate-ttl.sh
  40   '';
  41
  42   dontUseCmakeConfigure = true;
  43   enableParallelBuilding = true;
  44   strictDeps = true;
  45
  46   nativeBuildInputs = [
  47     cmake
  48     file
  49     pkg-config
  50     makeWrapper
  51     python3
  52   ];
  53
  54   buildInputs = [
  55     dbus
  56     fftwFloat
  57     freetype
  58     jansson
  59     libGL
  60     libX11
  61     libXcursor
  62     libXext
  63     libXrandr
  64     libarchive
  65     liblo
  66     libsamplerate
  67     libsndfile
  68     speexdsp
  69     libglvnd
  70   ];
  71
  72   hardeningDisable = [ "format" ];
  73   makeFlags =
  74     [
  75       "SYSDEPS=true"
  76       "PREFIX=$(out)"
  77     ]
  78     ++ lib.optional (stdenv.hostPlatform != stdenv.buildPlatform) "CROSS_COMPILING=true"
  79     ++ lib.optional headless "HEADLESS=true";
  80
  81   postInstall = ''
  82     wrapProgram $out/bin/Cardinal \
  83     --suffix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ libjack2 ]}
  84
  85     wrapProgram $out/bin/CardinalMini \
  86     --suffix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ libjack2 ]}
  87
  88     # this doesn't work and is mainly just a test tool for the developers anyway.
  89     rm -f $out/bin/CardinalNative
  90   '';
  91
  92   meta = {
  93     description = "Plugin wrapper around VCV Rack";
  94     homepage = "https://github.com/DISTRHO/cardinal";
  95     license = lib.licenses.gpl3;
  96     maintainers = with lib.maintainers; [
  97       magnetophon
  98       PowerUser64
  99     ];
 100     mainProgram = "Cardinal";
 101     platforms = lib.platforms.all;
 102     # never built on aarch64-darwin, x86_64-darwin since first introduction in nixpkgs
 103     broken = stdenv.hostPlatform.isDarwin;
 104   };
 105 }