pkgs/by-name/ca/cargo-tauri/test-app.nix

   1 {
   2   lib,
   3   stdenv,
   4   cargo-tauri,
   5   glib-networking,
   6   libayatana-appindicator,
   7   nodejs,
   8   openssl,
   9   pkg-config,
  10   pnpm_9,
  11   rustPlatform,
  12   webkitgtk_4_1,
  13   wrapGAppsHook4,
  14 }:
  15
  16 let
  17   pnpm = pnpm_9;
  18 in
  19 stdenv.mkDerivation (finalAttrs: {
  20   pname = "test-app";
  21   inherit (cargo-tauri) version src;
  22
  23   postPatch = lib.optionalString stdenv.hostPlatform.isLinux ''
  24     substituteInPlace $cargoDepsCopy/libappindicator-sys-*/src/lib.rs \
  25       --replace "libayatana-appindicator3.so.1" "${libayatana-appindicator}/lib/libayatana-appindicator3.so.1"
  26   '';
  27
  28   inherit (cargo-tauri) cargoDeps;
  29
  30   pnpmDeps = pnpm.fetchDeps {
  31     inherit (finalAttrs)
  32       pname
  33       version
  34       src
  35       ;
  36
  37     hash = "sha256-kTr61DFPIIYceB8tZrKFaMG65CZ//djGEOQBLRNPotk=";
  38   };
  39
  40   nativeBuildInputs = [
  41     cargo-tauri.hook
  42
  43     nodejs
  44     pkg-config
  45     pnpm.configHook
  46     rustPlatform.cargoCheckHook
  47     rustPlatform.cargoSetupHook
  48     wrapGAppsHook4
  49   ];
  50
  51   buildInputs =
  52     [ openssl ]
  53     ++ lib.optionals stdenv.hostPlatform.isLinux [
  54       glib-networking
  55       libayatana-appindicator
  56       webkitgtk_4_1
  57     ];
  58
  59   buildAndTestSubdir = "examples/api/src-tauri";
  60
  61   # This example depends on the actual `api` package to be built in-tree
  62   preBuild = ''
  63     pnpm --filter '@tauri-apps/api' build
  64   '';
  65
  66   # No one should be actually running this, so lets save some time
  67   buildType = "debug";
  68   doCheck = false;
  69
  70   meta = {
  71     inherit (cargo-tauri.hook.meta) platforms;
  72   };
  73 })