pkgs/by-name/ca/catppuccin-sddm/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchFromGitHub,
   5   just,
   6   kdePackages,
   7   flavor ? "mocha",
   8   font ? "Noto Sans",
   9   fontSize ? "9",
  10   background ? null,
  11   loginBackground ? false,
  12 }:
  13 stdenvNoCC.mkDerivation rec {
  14   pname = "catppuccin-sddm";
  15   version = "1.0.0";
  16
  17   src = fetchFromGitHub {
  18     owner = "catppuccin";
  19     repo = "sddm";
  20     rev = "v${version}";
  21     hash = "sha256-SdpkuonPLgCgajW99AzJaR8uvdCPi4MdIxS5eB+Q9WQ=";
  22   };
  23
  24   dontWrapQtApps = true;
  25
  26   nativeBuildInputs = [
  27     just
  28   ];
  29
  30   propagatedBuildInputs = [
  31     kdePackages.qtsvg
  32   ];
  33
  34   buildPhase = ''
  35     runHook preBuild
  36
  37     just build
  38
  39     runHook postBuild
  40   '';
  41
  42   installPhase = ''
  43     runHook preInstall
  44
  45     mkdir -p "$out/share/sddm/themes/"
  46     cp -r dist/catppuccin-${flavor} "$out/share/sddm/themes/catppuccin-${flavor}"
  47
  48     configFile=$out/share/sddm/themes/catppuccin-${flavor}/theme.conf
  49
  50     substituteInPlace $configFile \
  51       --replace-fail 'Font="Noto Sans"' 'Font="${font}"' \
  52       --replace-fail 'FontSize=9' 'FontSize=${fontSize}'
  53
  54     ${lib.optionalString (background != null) ''
  55       substituteInPlace $configFile \
  56         --replace-fail 'Background="backgrounds/wall.jpg"' 'Background="${background}"' \
  57         --replace-fail 'CustomBackground="false"' 'CustomBackground="true"'
  58     ''}
  59
  60     ${lib.optionalString loginBackground ''
  61       substituteInPlace $configFile \
  62         --replace-fail 'LoginBackground="false"' 'LoginBackground="true"'
  63     ''}
  64
  65     runHook postInstall
  66   '';
  67
  68   postFixup = ''
  69     mkdir -p $out/nix-support
  70     echo ${kdePackages.qtsvg} >> $out/nix-support/propagated-user-env-packages
  71   '';
  72
  73   meta = {
  74     description = "Soothing pastel theme for SDDM";
  75     homepage = "https://github.com/catppuccin/sddm";
  76     license = lib.licenses.mit;
  77     maintainers = with lib.maintainers; [elysasrc];
  78     platforms = lib.platforms.linux;
  79   };
  80 }