pkgs/by-name/co/cosmic-panel/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   just,
   6   pkg-config,
   7   rustPlatform,
   8   libglvnd,
   9   libxkbcommon,
  10   wayland,
  11 }:
  12
  13 rustPlatform.buildRustPackage rec {
  14   pname = "cosmic-panel";
  15   version = "1.0.0-alpha.5.1";
  16
  17   src = fetchFromGitHub {
  18     owner = "pop-os";
  19     repo = "cosmic-panel";
  20     tag = "epoch-${version}";
  21     hash = "sha256-nO7Y1SpwvfHhL0OSy7Ti+e8NPzfknW2SGs7IYoF1Jow=";
  22   };
  23
  24   useFetchCargoVendor = true;
  25   cargoHash = "sha256-EIp9s42deMaB7BDe7RAqj2+CnTXjHCtZjS5Iq8l46A4=";
  26
  27   nativeBuildInputs = [
  28     just
  29     pkg-config
  30   ];
  31   buildInputs = [
  32     libglvnd
  33     libxkbcommon
  34     wayland
  35   ];
  36
  37   dontUseJustBuild = true;
  38
  39   justFlags = [
  40     "--set"
  41     "prefix"
  42     (placeholder "out")
  43     "--set"
  44     "bin-src"
  45     "target/${stdenv.hostPlatform.rust.cargoShortTarget}/release/cosmic-panel"
  46   ];
  47
  48   # Force linking to libEGL, which is always dlopen()ed.
  49   "CARGO_TARGET_${stdenv.hostPlatform.rust.cargoEnvVarTarget}_RUSTFLAGS" =
  50     map (a: "-C link-arg=${a}")
  51       [
  52         "-Wl,--push-state,--no-as-needed"
  53         "-lEGL"
  54         "-Wl,--pop-state"
  55       ];
  56
  57   meta = with lib; {
  58     homepage = "https://github.com/pop-os/cosmic-panel";
  59     description = "Panel for the COSMIC Desktop Environment";
  60     mainProgram = "cosmic-panel";
  61     license = licenses.gpl3Only;
  62     maintainers = with maintainers; [
  63       qyliss
  64       nyabinary
  65     ];
  66     platforms = platforms.linux;
  67   };
  68 }