pkgs/by-name/cu/cups-brother-hll2375dw/package.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , dpkg
   5 , autoPatchelfHook
   6 , makeWrapper
   7 , perl
   8 , gnused
   9 , ghostscript
  10 , file
  11 , coreutils
  12 , gnugrep
  13 , which
  14 }:
  15
  16 let
  17   arches = [ "x86_64" "i686" "armv7l" ];
  18
  19   runtimeDeps = [
  20     ghostscript
  21     file
  22     gnused
  23     gnugrep
  24     coreutils
  25     which
  26   ];
  27 in
  28
  29 stdenv.mkDerivation rec {
  30   pname = "cups-brother-hll2375dw";
  31   version = "4.0.0-1";
  32
  33   nativeBuildInputs = [ dpkg makeWrapper autoPatchelfHook ];
  34   buildInputs = [ perl ];
  35
  36   src = fetchurl {
  37     url = "https://download.brother.com/welcome/dlf103535//hll2375dwpdrv-${version}.i386.deb";
  38     hash = "sha256-N5VCBZLFrfw29QjjzlSvQ12urvyaf7ez/RJ08UwqHdk=";
  39   };
  40
  41   patches = [
  42     # The brother lpdwrapper uses a temporary file to convey the printer settings.
  43     # The original settings file will be copied with "400" permissions and the "brprintconflsr3"
  44     # binary cannot alter the temporary file later on. This fixes the permissions so the can be modified.
  45     # Since this is all in briefly in the temporary directory of systemd-cups and not accessible by others,
  46     # it shouldn't be a security concern.
  47     ./fix-perm.patch
  48   ];
  49
  50   installPhase = ''
  51     runHook preInstall
  52     mkdir -p $out
  53     cp -ar opt $out/opt
  54     # delete unnecessary files for the current architecture
  55   '' + lib.concatMapStrings
  56     (arch: ''
  57       echo Deleting files for ${arch}
  58       rm -r "$out/opt/brother/Printers/HLL2375DW/lpd/${arch}"
  59     '')
  60     (builtins.filter (arch: arch != stdenv.hostPlatform.linuxArch) arches) + ''
  61     # bundled scripts don't understand the arch subdirectories for some reason
  62     ln -s \
  63       "$out/opt/brother/Printers/HLL2375DW/lpd/${stdenv.hostPlatform.linuxArch}/"* \
  64       "$out/opt/brother/Printers/HLL2375DW/lpd/"
  65
  66     # Fix global references and replace auto discovery mechanism with hardcoded values
  67     substituteInPlace $out/opt/brother/Printers/HLL2375DW/lpd/lpdfilter \
  68       --replace "my \$BR_PRT_PATH =" "my \$BR_PRT_PATH = \"$out/opt/brother/Printers/HLL2375DW\"; #" \
  69       --replace "PRINTER =~" "PRINTER = \"HLL2375DW\"; #"
  70     substituteInPlace $out/opt/brother/Printers/HLL2375DW/cupswrapper/lpdwrapper \
  71       --replace "my \$basedir = C" "my \$basedir = \"$out/opt/brother/Printers/HLL2375DW\" ; #" \
  72       --replace "PRINTER =~" "PRINTER = \"HLL2375DW\"; #"
  73
  74     # Make sure all executables have the necessary runtime dependencies available
  75     find "$out" -executable -and -type f | while read file; do
  76       wrapProgram "$file" --prefix PATH : "${lib.makeBinPath runtimeDeps}"
  77     done
  78
  79     # Symlink filter and ppd into a location where CUPS will discover it
  80     mkdir -p $out/lib/cups/filter
  81     mkdir -p $out/share/cups/model
  82     mkdir -p $out/etc/opt/brother/Printers/HLL2375DW/inf
  83
  84     ln -s $out/opt/brother/Printers/HLL2375DW/inf/brHLL2375DWrc \
  85           $out/etc/opt/brother/Printers/HLL2375DW/inf/brHLL2375DWrc
  86     ln -s \
  87       $out/opt/brother/Printers/HLL2375DW/cupswrapper/lpdwrapper \
  88       $out/lib/cups/filter/brother_lpdwrapper_HLL2375DW
  89     ln -s \
  90       $out/opt/brother/Printers/HLL2375DW/cupswrapper/brother-HLL2375DW-cups-en.ppd \
  91       $out/share/cups/model/
  92     runHook postInstall
  93   '';
  94
  95   meta = with lib; {
  96     homepage = "http://www.brother.com/";
  97     description = "Brother HLL2375DW printer driver";
  98     license = licenses.unfree;
  99     platforms = builtins.map (arch: "${arch}-linux") arches;
 100     maintainers = [ maintainers.gador ];
 101   };
 102 }