pkgs/by-name/cx/cxx-rs/package.nix

   1 {
   2   cxx-rs,
   3   fetchFromGitHub,
   4   lib,
   5   rustPlatform,
   6   testers,
   7 }:
   8
   9 rustPlatform.buildRustPackage rec {
  10   pname = "cxx-rs";
  11   version = "1.0.131";
  12
  13   src = fetchFromGitHub {
  14     owner = "dtolnay";
  15     repo = "cxx";
  16     rev = version;
  17     sha256 = "sha256-KQlbJvULdc94SM0sx6JtukZPpaX4Gojc6Qgr20V3/VI=";
  18   };
  19
  20   cargoLock = {
  21     lockFile = ./Cargo.lock;
  22   };
  23
  24   postPatch = ''
  25     cp ${./Cargo.lock} Cargo.lock
  26   '';
  27
  28   cargoBuildFlags = [
  29     "--workspace"
  30     "--exclude=demo"
  31   ];
  32
  33   postBuild = ''
  34     cargo doc --release
  35   '';
  36
  37   cargoTestFlags = [ "--workspace" ];
  38
  39   outputs = [
  40     "out"
  41     "doc"
  42     "dev"
  43   ];
  44
  45   postInstall = ''
  46     mkdir -p $doc
  47     cp -r ./target/doc/* $doc
  48
  49     mkdir -p $dev/include/rust
  50     install -D -m 0644 ./include/cxx.h $dev/include/rust
  51   '';
  52
  53   passthru.tests.version = testers.testVersion {
  54     package = cxx-rs;
  55     command = "cxxbridge --version";
  56   };
  57
  58   meta = with lib; {
  59     description = "Safe FFI between Rust and C++";
  60     mainProgram = "cxxbridge";
  61     homepage = "https://github.com/dtolnay/cxx";
  62     license = licenses.mit;
  63     maintainers = with maintainers; [ centromere ];
  64   };
  65 }