pkgs/by-name/db/dbqn/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   jdk,
   6   makeWrapper,
   7   buildNativeImage ? false,
   8 }:
   9
  10 stdenv.mkDerivation rec {
  11   pname = "dbqn" + lib.optionalString buildNativeImage "-native";
  12   version = "0.2.2";
  13
  14   src = fetchFromGitHub {
  15     owner = "dzaima";
  16     repo = "BQN";
  17     rev = "v${version}";
  18     hash = "sha256-AUfT7l7zr/pyG63wX8FMej8RUg7tXC1aroCrunjyw/8=";
  19   };
  20
  21   nativeBuildInputs = [
  22     jdk
  23     makeWrapper
  24   ];
  25
  26   dontConfigure = true;
  27
  28   postPatch = ''
  29     patchShebangs --build ./build8
  30   '';
  31
  32   buildPhase =
  33     ''
  34       runHook preBuild
  35
  36       ./build8
  37     ''
  38     + lib.optionalString buildNativeImage ''
  39       native-image --report-unsupported-elements-at-runtime \
  40         -H:CLibraryPath=${lib.getLib jdk}/lib -J-Dfile.encoding=UTF-8 \
  41         -jar BQN.jar dbqn
  42     ''
  43     + ''
  44       runHook postBuild
  45     '';
  46
  47   installPhase =
  48     ''
  49       runHook preInstall
  50
  51       mkdir -p $out/bin
  52
  53     ''
  54     + (
  55       if buildNativeImage then
  56         ''
  57           mv dbqn $out/bin
  58         ''
  59       else
  60         ''
  61           mkdir -p $out/share/dbqn
  62           mv BQN.jar $out/share/dbqn/
  63
  64           makeWrapper "${lib.getBin jdk}/bin/java" "$out/bin/dbqn" \
  65             --add-flags "-jar $out/share/dbqn/BQN.jar"
  66         ''
  67     )
  68     + ''
  69       ln -s $out/bin/dbqn $out/bin/bqn
  70
  71       runHook postInstall
  72     '';
  73
  74   meta = with lib; {
  75     homepage = "https://github.com/dzaima/BQN";
  76     description =
  77       "BQN implementation in Java" + lib.optionalString buildNativeImage ", compiled as a native image";
  78     license = licenses.mit;
  79     maintainers = with maintainers; [
  80       AndersonTorres
  81       sternenseemann
  82     ];
  83     inherit (jdk.meta) platforms;
  84     broken = stdenv.hostPlatform.isDarwin; # never built on Hydra https://hydra.nixos.org/job/nixpkgs/staging-next/dbqn-native.x86_64-darwin
  85   };
  86 }
  87 # TODO: Processing app
  88 # TODO: minimalistic JDK