pkgs/by-name/dl/dleyna-renderer/package.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , fetchpatch
   5 , meson
   6 , ninja
   7 , pkg-config
   8 , dleyna-connector-dbus
   9 , dleyna-core
  10 , gssdp
  11 , gupnp
  12 , gupnp-av
  13 , gupnp-dlna
  14 , libsoup
  15 , makeWrapper
  16 , docbook-xsl-nons
  17 , libxslt
  18 }:
  19
  20 stdenv.mkDerivation rec {
  21   pname = "dleyna-renderer";
  22   version = "0.7.2";
  23
  24   src = fetchFromGitHub {
  25     owner = "phako";
  26     repo = pname;
  27     rev = "v${version}";
  28     sha256 = "sha256-bGasT3XCa7QHV3D7z59TSHoqWksNSIgaO0z9zYfHHuw=";
  29   };
  30
  31   patches = [
  32     # Fix build with meson 1.2. We use the gentoo patch intead of the
  33     # usptream one because the latter only applies on the libsoup_3 based
  34     # merged dLeyna project.
  35     # https://gitlab.gnome.org/World/dLeyna/-/merge_requests/6
  36     (fetchpatch {
  37       url = "https://github.com/gentoo/gentoo/raw/2ebe20ff4cda180cc248d31a021107d08ecf39d9/net-libs/dleyna-renderer/files/meson-1.2.0.patch";
  38       sha256 = "sha256-/p2OaPO5ghWtPotwIir2TtcFF5IDFN9FFuyqPHevuFI=";
  39     })
  40   ];
  41
  42   nativeBuildInputs = [
  43     meson
  44     ninja
  45     pkg-config
  46     makeWrapper
  47
  48     # manpage
  49     docbook-xsl-nons
  50     libxslt # for xsltproc
  51   ];
  52
  53   buildInputs = [
  54     dleyna-core
  55     dleyna-connector-dbus # runtime dependency to be picked up to DLEYNA_CONNECTOR_PATH
  56     gssdp
  57     gupnp
  58     gupnp-av
  59     gupnp-dlna
  60     libsoup
  61   ];
  62
  63   preFixup = ''
  64     wrapProgram "$out/libexec/dleyna-renderer-service" \
  65       --set DLEYNA_CONNECTOR_PATH "$DLEYNA_CONNECTOR_PATH"
  66   '';
  67
  68   meta = with lib; {
  69     description = "Library to discover and manipulate Digital Media Renderers";
  70     homepage = "https://github.com/phako/dleyna-renderer";
  71     maintainers = with maintainers; [ jtojnar ];
  72     platforms = platforms.unix;
  73     license = licenses.lgpl21Only;
  74   };
  75 }