pkgs/by-name/fe/fermyon-spin/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   autoPatchelfHook,
   6   gcc-unwrapped,
   7   zlib,
   8 }:
   9
  10 let
  11   system = stdenv.hostPlatform.system;
  12
  13   platform =
  14     {
  15       x86_64-linux = "linux-amd64";
  16       aarch64-linux = "linux-aarch64";
  17       x86_64-darwin = "macos-amd64";
  18       aarch64-darwin = "macos-aarch64";
  19     }
  20     .${system} or (throw "Unsupported system: ${system}");
  21
  22   # TODO: It'd be nice to write an update script that would update all of these
  23   # hashes together.
  24   packageHash =
  25     {
  26       x86_64-linux = "sha256-r/F3Tj3WeeL2R27ussX+ebFWpW+8z2e7tdBK4MHFMpk=";
  27       aarch64-linux = "sha256-BSFxDJeY7fOOxDqAV+6FJf0hup1Y5IJ/czqwc4W7qSA=";
  28       x86_64-darwin = "sha256-T6J9IjfXdt9DnZksndAmZRkYyH/5H60J7V6xU0ltD2A=";
  29       aarch64-darwin = "sha256-6x+0PB5/2oqYDVNiNhc0xcs/ESCLvvSsWtm2KlTIeBo=";
  30     }
  31     .${system} or (throw "Unsupported system: ${system}");
  32
  33 in
  34 stdenv.mkDerivation rec {
  35   pname = "fermyon-spin";
  36   version = "3.0.0";
  37
  38   # Use fetchurl rather than fetchzip as these tarballs are built by the project
  39   # and not by GitHub (and thus are stable) - this simplifies the update script
  40   # by allowing it to use the output of `nix store prefetch-file`.
  41   src = fetchurl {
  42     url = "https://github.com/fermyon/spin/releases/download/v${version}/spin-v${version}-${platform}.tar.gz";
  43     hash = packageHash;
  44   };
  45
  46   sourceRoot = ".";
  47
  48   nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [
  49     autoPatchelfHook
  50   ];
  51
  52   buildInputs = [
  53     gcc-unwrapped.lib
  54     zlib
  55   ];
  56
  57   installPhase = ''
  58     runHook preInstall
  59
  60     mkdir -p $out/bin
  61     cp ./spin $out/bin
  62
  63     runHook postInstall
  64   '';
  65
  66   meta = with lib; {
  67     description = "Framework for building, deploying, and running fast, secure, and composable cloud microservices with WebAssembly";
  68     homepage = "https://github.com/fermyon/spin";
  69     sourceProvenance = with sourceTypes; [ binaryNativeCode ];
  70     license = with licenses; [ asl20 ];
  71     mainProgram = "spin";
  72     maintainers = with maintainers; [ mglolenstine ];
  73     platforms = platforms.linux ++ platforms.darwin;
  74   };
  75 }