pkgs/by-name/fi/find-billy/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchFromGitea,
   5   godot3-headless,
   6   godot3-export-templates,
   7   godot3,
   8   makeWrapper,
   9   just,
  10   inkscape,
  11   imagemagick,
  12 }:
  13
  14 stdenv.mkDerivation rec {
  15   pname = "find-billy";
  16   version = "0.37.3";
  17
  18   src = fetchFromGitea {
  19     domain = "codeberg.org";
  20     owner = "annaaurora";
  21     repo = "Find-Billy";
  22     rev = "v${version}";
  23     hash = "sha256-z1GR5W67LJb5z+u/qeFZreMK4B6PjB18coecLCYFHy8=";
  24   };
  25
  26   strictDeps = true;
  27
  28   nativeBuildInputs = [
  29     godot3-headless
  30     makeWrapper
  31     just
  32     inkscape
  33     imagemagick
  34   ];
  35
  36   postPatch = ''
  37     substituteInPlace export_presets.cfg --replace 'res://build/icons/usr/share/icons/hicolor' $out/share/icons/hicolor
  38     substituteInPlace project.godot --replace 'res://build/icons/usr/share/icons/hicolor' $out/share/icons/hicolor
  39
  40     substituteInPlace justfile --replace '{{build_icons_dir}}/usr' $out
  41   '';
  42
  43   buildPhase = ''
  44     runHook preBuild
  45
  46     # Cannot create file `/homeless-shelter/.config/godot/projects/...`
  47     export HOME=$TMPDIR
  48     # Link the export-templates to the expected location. The `--export` option expects the templates in the home directory.
  49     mkdir -p $HOME/.local/share/godot
  50     ln -s ${godot3-export-templates}/share/godot/templates $HOME/.local/share/godot
  51
  52     mkdir -p $out/share/find-billy
  53     godot3-headless --export-pack 'Linux/X11' $out/share/find-billy/find-billy.pck
  54     makeWrapper ${godot3}/bin/godot3 $out/bin/find-billy \
  55       --add-flags "--main-pack" \
  56       --add-flags "$out/share/find-billy/find-billy.pck"
  57
  58     runHook postBuild
  59   '';
  60
  61   installPhase = ''
  62     runHook preInstall
  63
  64     just build-icons
  65     install -D find-billy.desktop -t $out/share/applications
  66
  67     runHook postInstall
  68   '';
  69
  70   meta = with lib; {
  71     description = "2 dimensional Pixel Art Jump & Run";
  72     homepage = "https://codeberg.org/annaaurora/Find-Billy";
  73     license = licenses.gpl3Plus;
  74     platforms = [ "x86_64-linux" ];
  75     maintainers = [ maintainers.annaaurora ];
  76   };
  77 }