pkgs/by-name/fl/fluent-bit/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   cmake,
   6   flex,
   7   bison,
   8   systemd,
   9   postgresql,
  10   openssl,
  11   libyaml,
  12   darwin,
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "fluent-bit";
  17   version = "3.2.4";
  18
  19   src = fetchFromGitHub {
  20     owner = "fluent";
  21     repo = "fluent-bit";
  22     rev = "v${finalAttrs.version}";
  23     hash = "sha256-oTCGjDmGVovsfj+4fjIKy/xpiuYc0Q44LYwYPI4dSF8=";
  24   };
  25
  26   # optional only to avoid linux rebuild
  27   patches = lib.optionals stdenv.hostPlatform.isDarwin [ ./macos-11-sdk-compat.patch ];
  28
  29   nativeBuildInputs = [
  30     cmake
  31     flex
  32     bison
  33   ];
  34
  35   buildInputs =
  36     [
  37       openssl
  38       libyaml
  39       postgresql
  40     ]
  41     ++ lib.optionals stdenv.hostPlatform.isLinux [ systemd ]
  42     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  43       darwin.apple_sdk_11_0.frameworks.IOKit
  44       darwin.apple_sdk_11_0.frameworks.Foundation
  45     ];
  46
  47   cmakeFlags = [
  48     "-DFLB_RELEASE=ON"
  49     "-DFLB_METRICS=ON"
  50     "-DFLB_HTTP_SERVER=ON"
  51     "-DFLB_OUT_PGSQL=ON"
  52   ];
  53
  54   env.NIX_CFLAGS_COMPILE = toString (
  55     # Assumes GNU version of strerror_r, and the posix version has an
  56     # incompatible return type.
  57     lib.optionals (!stdenv.hostPlatform.isGnu) [ "-Wno-int-conversion" ]
  58   );
  59
  60   outputs = [
  61     "out"
  62     "dev"
  63   ];
  64
  65   postPatch = ''
  66     substituteInPlace src/CMakeLists.txt \
  67       --replace /lib/systemd $out/lib/systemd
  68   '';
  69
  70   meta = {
  71     changelog = "https://github.com/fluent/fluent-bit/releases/tag/v${finalAttrs.version}";
  72     description = "Log forwarder and processor, part of Fluentd ecosystem";
  73     homepage = "https://fluentbit.io";
  74     license = lib.licenses.asl20;
  75     maintainers = with lib.maintainers; [
  76       samrose
  77       fpletz
  78     ];
  79     platforms = lib.platforms.unix;
  80   };
  81 })