pkgs/by-name/fl/flyctl/package.nix

   1 {
   2   lib,
   3   buildGoModule,
   4   fetchFromGitHub,
   5   testers,
   6   flyctl,
   7   installShellFiles,
   8 }:
   9
  10 buildGoModule rec {
  11   pname = "flyctl";
  12   version = "0.3.75";
  13
  14   src = fetchFromGitHub {
  15     owner = "superfly";
  16     repo = "flyctl";
  17     rev = "v${version}";
  18     hash = "sha256-uNJzJpeJpDNDgnBIzveK2dKVdRpEWFW912c/vZgeXQo=";
  19   };
  20
  21   vendorHash = "sha256-ylz8O/HW1rtOCI6/YzIT/byYmSdMkSrF0AX7nIzALTU=";
  22
  23   subPackages = [ "." ];
  24
  25   ldflags = [
  26     "-s"
  27     "-w"
  28     "-X github.com/superfly/flyctl/internal/buildinfo.buildDate=1970-01-01T00:00:00Z"
  29     "-X github.com/superfly/flyctl/internal/buildinfo.buildVersion=${version}"
  30   ];
  31   tags = [ "production" ];
  32
  33   nativeBuildInputs = [ installShellFiles ];
  34
  35   patches = [ ./disable-auto-update.patch ];
  36
  37   preBuild = ''
  38     GOOS= GOARCH= CGO_ENABLED=0 go generate ./...
  39   '';
  40
  41   preCheck = ''
  42     HOME=$(mktemp -d)
  43   '';
  44
  45   # We override checkPhase to be able to test ./... while using subPackages
  46   checkPhase = ''
  47     runHook preCheck
  48     # We do not set trimpath for tests, in case they reference test assets
  49     export GOFLAGS=''${GOFLAGS//-trimpath/}
  50
  51     buildGoDir test ./...
  52
  53     runHook postCheck
  54   '';
  55
  56   postInstall = ''
  57     installShellCompletion --cmd flyctl \
  58       --bash <($out/bin/flyctl completion bash) \
  59       --fish <($out/bin/flyctl completion fish) \
  60       --zsh <($out/bin/flyctl completion zsh)
  61     ln -s $out/bin/flyctl $out/bin/fly
  62   '';
  63
  64   passthru.tests.version = testers.testVersion {
  65     package = flyctl;
  66     command = "HOME=$(mktemp -d) flyctl version";
  67     version = "v${flyctl.version}";
  68   };
  69
  70   meta = {
  71     description = "Command line tools for fly.io services";
  72     downloadPage = "https://github.com/superfly/flyctl";
  73     homepage = "https://fly.io/";
  74     license = lib.licenses.asl20;
  75     maintainers = with lib.maintainers; [
  76       adtya
  77       jsierles
  78       techknowlogick
  79       RaghavSood
  80       teutat3s
  81     ];
  82     mainProgram = "flyctl";
  83   };
  84 }