pkgs/by-name/fo/forgejo-runner/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   buildGoModule,
   5   fetchFromGitea,
   6   nixosTests,
   7   versionCheckHook,
   8   nix-update-script,
   9 }:
  10
  11 let
  12   # tests which assume network access in some form
  13   disabledTests = [
  14     "Test_runCreateRunnerFile"
  15     "Test_ping"
  16   ];
  17 in
  18 buildGoModule rec {
  19   pname = "forgejo-runner";
  20   version = "6.2.0";
  21
  22   src = fetchFromGitea {
  23     domain = "code.forgejo.org";
  24     owner = "forgejo";
  25     repo = "runner";
  26     rev = "v${version}";
  27     hash = "sha256-2+/PJZPqKbxeWbIVx2647/xK5CqVUUvsdd67YFwjhms=";
  28   };
  29
  30   vendorHash = "sha256-wvvzD2lD1TPXEriNaI6nzNGR/Kg94zC58pAR42/DlMA=";
  31
  32   ldflags = [
  33     "-s"
  34     "-w"
  35     "-X gitea.com/gitea/act_runner/internal/pkg/ver.version=${src.rev}"
  36   ];
  37
  38   checkFlags = [
  39     "-skip ${lib.concatStringsSep "|" disabledTests}"
  40   ];
  41
  42   doInstallCheck = true;
  43   nativeInstallCheckInputs = [ versionCheckHook ];
  44   versionCheckProgram = "${placeholder "out"}/bin/${meta.mainProgram}";
  45   versionCheckProgramArg = [ "--version" ];
  46
  47   passthru = {
  48     updateScript = nix-update-script { };
  49     tests = lib.optionalAttrs stdenv.hostPlatform.isLinux {
  50       sqlite3 = nixosTests.forgejo.sqlite3;
  51     };
  52   };
  53
  54   meta = with lib; {
  55     description = "Runner for Forgejo based on act";
  56     homepage = "https://code.forgejo.org/forgejo/runner";
  57     changelog = "https://code.forgejo.org/forgejo/runner/src/tag/${src.rev}/RELEASE-NOTES.md";
  58     license = licenses.mit;
  59     maintainers = with maintainers; [
  60       adamcstephens
  61       emilylange
  62       christoph-heiss
  63     ];
  64     mainProgram = "act_runner";
  65   };
  66 }