pkgs/by-name/fs/fsuae-launcher/package.nix

   1 {
   2   lib,
   3   fetchurl,
   4   fsuae,
   5   gettext,
   6   python3Packages,
   7   stdenv,
   8   libsForQt5,
   9 }:
  10
  11 stdenv.mkDerivation (finalAttrs: {
  12   pname = "fs-uae-launcher";
  13   version = "3.1.70";
  14
  15   src = fetchurl {
  16     url = "https://fs-uae.net/files/FS-UAE-Launcher/Stable/${finalAttrs.version}/fs-uae-launcher-${finalAttrs.version}.tar.xz";
  17     hash = "sha256-yvJ8sa44V13SEUJ6C9SgS+N2ZFH5+20TTL2ICY9A36c=";
  18   };
  19
  20   nativeBuildInputs = [
  21     gettext
  22     python3Packages.python
  23     libsForQt5.wrapQtAppsHook
  24   ];
  25
  26   buildInputs = with python3Packages; [
  27     pyqt5
  28     requests
  29     setuptools
  30   ];
  31
  32   strictDeps = true;
  33
  34   makeFlags = [ "prefix=$(out)" ];
  35
  36   dontWrapQtApps = true;
  37
  38   postPatch = ''
  39     substituteInPlace setup.py \
  40       --replace-fail "distutils.core" "setuptools"
  41   '';
  42
  43   preFixup = ''
  44     wrapQtApp "$out/bin/fs-uae-launcher" \
  45       --set PYTHONPATH "$PYTHONPATH"
  46
  47     # fs-uae-launcher search side by side for executables and shared files
  48     # see $src/fsgs/plugins/pluginexecutablefinder.py#find_executable
  49     ln -s ${fsuae}/bin/fs-uae $out/bin
  50     ln -s ${fsuae}/bin/fs-uae-device-helper $out/bin
  51     ln -s ${fsuae}/share/fs-uae $out/share/fs-uae
  52   '';
  53
  54   meta = {
  55     homepage = "https://fs-uae.net";
  56     description = "Graphical front-end for the FS-UAE emulator";
  57     license = lib.licenses.gpl2Plus;
  58     mainProgram = "fs-uae-launcher";
  59     maintainers = with lib.maintainers; [
  60       sander
  61       AndersonTorres
  62     ];
  63     platforms = with lib.systems.inspect; patternLogicalAnd patterns.isx86 patterns.isLinux;
  64   };
  65 })