pkgs/by-name/ft/ftjam/package.nix

   1 {
   2   lib,
   3   bison,
   4   buildPackages,
   5   fetchurl,
   6   installShellFiles,
   7   pkgsBuildTarget,
   8   stdenv,
   9   testers,
  10 }:
  11
  12 stdenv.mkDerivation (finalAttrs: {
  13   pname = "ftjam";
  14   version = "2.5.2";
  15
  16   src = fetchurl {
  17     url = "mirror://sourceforge/project/freetype/ftjam/${finalAttrs.version}/ftjam-${finalAttrs.version}.tar.bz2";
  18     hash = "sha256-6JdzUAqSkS3pGOn+v/q+S2vOedaa8ZRDX04DK4ptZqM=";
  19   };
  20
  21   depsBuildBuild = [ buildPackages.stdenv.cc ];
  22
  23   nativeBuildInputs = [
  24     bison
  25     installShellFiles
  26   ];
  27
  28   # Doesn't understand how to cross compile once bootstrapped, so we'll just use
  29   # the Makefile for the bootstrapping portion
  30   configurePlatforms = [
  31     "build"
  32     "target"
  33   ];
  34
  35   configureFlags = [
  36     "CC=${buildPackages.stdenv.cc.targetPrefix}cc"
  37     "--host=${stdenv.buildPlatform.config}"
  38   ];
  39
  40   makeFlags = [
  41     "CC=${buildPackages.stdenv.cc.targetPrefix}cc"
  42   ];
  43
  44   env = {
  45     LOCATE_TARGET = "bin.unix";
  46     # Jam uses c89 conventions
  47     NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-std=c89";
  48   };
  49
  50   enableParallelBuilding = true;
  51
  52   strictDeps = true;
  53
  54   # Jambase expects ar to have flags.
  55   preConfigure = ''
  56     export AR="$AR rc"
  57   '';
  58
  59   # When cross-compiling, we need to set the preprocessor macros
  60   # OSMAJOR/OSMINOR/OSPLAT to the values from the target platform, not the host
  61   # platform. This looks a little ridiculous because the vast majority of build
  62   # tools don't embed target-specific information into their binary, but in this
  63   # case we behave more like a compiler than a make(1)-alike.
  64   postPatch =
  65     ''
  66       substituteInPlace Jamfile \
  67         --replace "strip" "${stdenv.cc.targetPrefix}strip"
  68     ''
  69     + lib.optionalString (stdenv.hostPlatform != stdenv.targetPlatform) ''
  70       cat >>jam.h <<EOF
  71       #undef OSMAJOR
  72       #undef OSMINOR
  73       #undef OSPLAT
  74       $(
  75          ${pkgsBuildTarget.targetPackages.stdenv.cc}/bin/${pkgsBuildTarget.targetPackages.stdenv.cc.targetPrefix}cc -E -dM jam.h | grep -E '^#define (OSMAJOR|OSMINOR|OSPLAT) '
  76       )
  77       EOF
  78     '';
  79
  80   buildPhase = ''
  81     runHook preBuild
  82     make $makeFlags jam0
  83     ./jam0 -j$NIX_BUILD_CORES -sCC=${buildPackages.stdenv.cc.targetPrefix}cc jambase.c
  84     ./jam0 -j$NIX_BUILD_CORES
  85     runHook postBuild
  86   '';
  87
  88   # The configure script does not recognize --docdir; because of it, the outputs
  89   # can't be split
  90   installPhase = ''
  91     runHook preInstall
  92
  93     installBin bin.unix/jam
  94     install -Dm644 -t ''${!outputDoc}/share/doc/jam-${finalAttrs.version}/ *.html
  95
  96     runHook postInstall
  97   '';
  98
  99   passthru = {
 100     tests.version = testers.testVersion {
 101       package = finalAttrs.finalPackage;
 102       command = "jam -v";
 103     };
 104   };
 105
 106   meta = {
 107     homepage = "https://freetype.org/jam/";
 108     description = "FreeType's enhanced, backwards-compatible Jam clone";
 109     license = lib.licenses.free;
 110     mainProgram = "jam";
 111     maintainers = with lib.maintainers; [
 112       impl
 113       AndersonTorres
 114     ];
 115     platforms = lib.platforms.unix;
 116   };
 117 })