pkgs/by-name/ge/germinal/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , appstream-glib
   5 , autoreconfHook
   6 , dbus
   7 , pango
   8 , pcre2
   9 , pkg-config
  10 , tmux
  11 , vte
  12 , wrapGAppsHook3
  13 , nixosTests
  14 }:
  15
  16 stdenv.mkDerivation (finalAttrs: {
  17   pname = "germinal";
  18   version = "26";
  19
  20   src = fetchFromGitHub {
  21     owner = "Keruspe";
  22     repo = "Germinal";
  23     rev = "v${finalAttrs.version}";
  24     hash = "sha256-HUi+skF4bJj5CY2cNTOC4tl7jhvpXYKqBx2rqKzjlo0=";
  25   };
  26
  27   nativeBuildInputs = [
  28     autoreconfHook
  29     pkg-config
  30     wrapGAppsHook3
  31   ];
  32
  33   buildInputs = [
  34     appstream-glib
  35     dbus
  36     pango
  37     pcre2
  38     vte
  39   ];
  40
  41   configureFlags = [
  42     "--with-dbusservicesdir=${placeholder "out"}/etc/dbus-1/system-services/"
  43   ];
  44
  45   dontWrapGApps = true;
  46
  47   fixupPhase = ''
  48     runHook preFixup
  49     wrapProgram $out/bin/germinal \
  50      --prefix PATH ":" "${lib.makeBinPath [ tmux ]}" \
  51       "''${gappsWrapperArgs[@]}"
  52     runHook postFixup
  53   '';
  54
  55   passthru.tests.test = nixosTests.terminal-emulators.germinal;
  56
  57   meta = {
  58     description = "Minimal terminal emulator";
  59     homepage = "https://github.com/Keruspe/Germinal";
  60     license = lib.licenses.gpl3Plus;
  61     mainProgram = "germinal";
  62     maintainers = with lib.maintainers; [ AndersonTorres ];
  63     platforms = lib.platforms.unix;
  64   };
  65 })