pkgs/by-name/gi/gitmoji-cli/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , fetchYarnDeps
   5 , makeWrapper
   6 , nodejs
   7 , fixup-yarn-lock
   8 , yarn
   9 , testers
  10 }:
  11
  12 stdenv.mkDerivation (finalAttrs: {
  13   pname = "gitmoji-cli";
  14   version = "9.0.0";
  15
  16   src = fetchFromGitHub {
  17     owner = "carloscuesta";
  18     repo = "gitmoji-cli";
  19     rev = "v${finalAttrs.version}";
  20     hash = "sha256-cIc0AaP1AwhoVJLnonC9qvDWNZW4L6/jsQ3Q6z5VXI0=";
  21   };
  22
  23   offlineCache = fetchYarnDeps {
  24     yarnLock = "${finalAttrs.src}/yarn.lock";
  25     hash = "sha256-HXMRCTiUti/GZ1dzd+XbFOao3+QLC1t7H0TT9MS5lz4=";
  26   };
  27
  28   nativeBuildInputs = [
  29     makeWrapper
  30     nodejs
  31     fixup-yarn-lock
  32     yarn
  33   ];
  34
  35   configurePhase = ''
  36     runHook preConfigure
  37
  38     export HOME=$(mktemp -d)
  39     yarn config --offline set yarn-offline-mirror $offlineCache
  40     fixup-yarn-lock yarn.lock
  41     yarn --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive install
  42     patchShebangs node_modules
  43
  44     runHook postConfigure
  45   '';
  46
  47   buildPhase = ''
  48     runHook preBuild
  49
  50     yarn --offline build
  51
  52     runHook postBuild
  53   '';
  54
  55   installPhase = ''
  56     runHook preInstall
  57
  58     yarn --offline --production install
  59
  60     mkdir -p "$out/lib/node_modules/gitmoji-cli"
  61     cp -r lib node_modules package.json "$out/lib/node_modules/gitmoji-cli"
  62
  63     makeWrapper "${nodejs}/bin/node" "$out/bin/gitmoji" \
  64       --add-flags "$out/lib/node_modules/gitmoji-cli/lib/cli.js"
  65
  66     runHook postInstall
  67   '';
  68
  69   passthru.tests = {
  70     version = testers.testVersion {
  71       package = finalAttrs.finalPackage;
  72     };
  73   };
  74
  75   meta = {
  76     description = "Gitmoji client for using emojis on commit messages";
  77     homepage = "https://github.com/carloscuesta/gitmoji-cli";
  78     license = lib.licenses.mit;
  79     mainProgram = "gitmoji";
  80     maintainers = with lib.maintainers; [ nequissimus ];
  81   };
  82 })