pkgs/by-name/gn/gnujump/package.nix

   1 { lib, stdenv, makeDesktopItem, copyDesktopItems, fetchurl, SDL, SDL_image, SDL_mixer }:
   2
   3 stdenv.mkDerivation (finalAttrs: {
   4   pname = "gnujump";
   5   version = "1.0.8";
   6   src = fetchurl {
   7     url = "mirror://gnu/gnujump/gnujump-${finalAttrs.version}.tar.gz";
   8     sha256 = "05syy9mzbyqcfnm0hrswlmhwlwx54f0l6zhcaq8c1c0f8dgzxhqk";
   9   };
  10
  11   nativeBuildInputs = [ copyDesktopItems ];
  12   buildInputs = [ SDL SDL_image SDL_mixer ];
  13
  14   NIX_LDFLAGS = "-lm";
  15
  16   desktopItems = [ (makeDesktopItem {
  17     name = "gnujump";
  18     exec = "gnujump";
  19     icon = "gnujump";
  20     desktopName = "GNUjump";
  21     comment     = "Jump up the tower to survive";
  22     categories  = [ "Game" "ArcadeGame" ];
  23   }) ];
  24
  25   postInstall = ''
  26     install -Dm644 ${./gnujump.xpm} $out/share/pixmaps/gnujump.xpm
  27   '';
  28
  29   meta = with lib; {
  30     homepage = "https://jump.gnu.sinusoid.es/index.php?title=Main_Page";
  31     description = "Clone of the simple yet addictive game Xjump";
  32     mainProgram = "gnujump";
  33     longDescription = ''
  34       The goal in this game is to jump to the next floor trying not to fall
  35       down. As you go upper in the Falling Tower the floors will fall faster.
  36       Try to survive longer get upper than anyone. It might seem too simple but
  37       once you've tried you'll realize how addictive this is.
  38     '';
  39     license = licenses.gpl3;
  40     maintainers = with maintainers; [ fgaz ];
  41     platforms = platforms.linux;
  42   };
  43 })