pkgs/by-name/go/go-ethereum/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   buildGoModule,
   5   fetchFromGitHub,
   6   libobjc,
   7   IOKit,
   8   nixosTests,
   9 }:
  10
  11 let
  12   # A list of binaries to put into separate outputs
  13   bins = [
  14     "geth"
  15     "clef"
  16   ];
  17
  18 in
  19 buildGoModule rec {
  20   pname = "go-ethereum";
  21   version = "1.14.12";
  22
  23   src = fetchFromGitHub {
  24     owner = "ethereum";
  25     repo = pname;
  26     rev = "v${version}";
  27     hash = "sha256-s1BSFTjqro3gFyKphU8FdpjViKyyZc0bt1m+lzkAcBU=";
  28   };
  29
  30   proxyVendor = true;
  31   vendorHash = "sha256-IEwy3XRyj+5GjAWRjPsd5qzwEMpI/pZIwPjKdeATgkE=";
  32
  33   doCheck = false;
  34
  35   outputs = [ "out" ] ++ bins;
  36
  37   # Move binaries to separate outputs and symlink them back to $out
  38   postInstall = lib.concatStringsSep "\n" (
  39     builtins.map (
  40       bin:
  41       "mkdir -p \$${bin}/bin && mv $out/bin/${bin} \$${bin}/bin/ && ln -s \$${bin}/bin/${bin} $out/bin/"
  42     ) bins
  43   );
  44
  45   subPackages = [
  46     "cmd/abidump"
  47     "cmd/abigen"
  48     "cmd/blsync"
  49     "cmd/bootnode"
  50     "cmd/clef"
  51     "cmd/devp2p"
  52     "cmd/era"
  53     "cmd/ethkey"
  54     "cmd/evm"
  55     "cmd/geth"
  56     "cmd/rlpdump"
  57     "cmd/utils"
  58   ];
  59
  60   # Following upstream: https://github.com/ethereum/go-ethereum/blob/v1.11.6/build/ci.go#L218
  61   tags = [ "urfave_cli_no_docs" ];
  62
  63   # Fix for usb-related segmentation faults on darwin
  64   propagatedBuildInputs = lib.optionals stdenv.hostPlatform.isDarwin [
  65     libobjc
  66     IOKit
  67   ];
  68
  69   passthru.tests = { inherit (nixosTests) geth; };
  70
  71   meta = with lib; {
  72     homepage = "https://geth.ethereum.org/";
  73     description = "Official golang implementation of the Ethereum protocol";
  74     license = with licenses; [
  75       lgpl3Plus
  76       gpl3Plus
  77     ];
  78     maintainers = with maintainers; [ RaghavSood ];
  79     mainProgram = "geth";
  80   };
  81 }