pkgs/by-name/go/google-fonts/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchFromGitHub,
   5   fonts ? [ ],
   6 }:
   7
   8 stdenvNoCC.mkDerivation {
   9   pname = "google-fonts";
  10   version = "unstable-2024-06-21";
  11
  12   # Adobe Blank is split out in a separate output,
  13   # because it causes crashes with `libfontconfig`.
  14   # It has an absurd number of symbols
  15   outputs = [
  16     "out"
  17     "adobeBlank"
  18   ];
  19
  20   src = fetchFromGitHub {
  21     owner = "google";
  22     repo = "fonts";
  23     rev = "d5ea3092960d3d5db0b7a9890c828bafbf159c51";
  24     hash = "sha256-jQVwAgrZzdCVD4aaX4vYJLqj67t9vn60bYPuBWWMbBg=";
  25   };
  26
  27   postPatch = ''
  28     # These directories need to be removed because they contain
  29     # older or duplicate versions of fonts also present in other
  30     # directories. This causes non-determinism in the install since
  31     # the installation order of font files with the same name is not
  32     # fixed.
  33     rm -rv ofl/cabincondensed \
  34       ofl/signikanegative \
  35       ofl/signikanegativesc \
  36       ofl/*_todelist \
  37       axisregistry/tests/data
  38
  39     if find . -name "*.ttf" | sed 's|.*/||' | sort | uniq -c | sort -n | grep -v '^.*1 '; then
  40       echo "error: duplicate font names"
  41       exit 1
  42     fi
  43   '';
  44
  45   dontBuild = true;
  46
  47   # The font files are in the fonts directory and use three naming schemes:
  48   # FamilyName-StyleName.ttf, FamilyName[param1,param2,...].ttf, and
  49   # FamilyName.ttf. This installs all fonts if fonts is empty and otherwise
  50   # only the specified fonts by FamilyName.
  51   fonts = map (font: builtins.replaceStrings [ " " ] [ "" ] font) fonts;
  52   installPhase =
  53     ''
  54       adobeBlankDest=$adobeBlank/share/fonts/truetype
  55       install -m 444 -Dt $adobeBlankDest ofl/adobeblank/AdobeBlank-Regular.ttf
  56       rm -r ofl/adobeblank
  57       dest=$out/share/fonts/truetype
  58     ''
  59     + (
  60       if fonts == [ ] then
  61         ''
  62           find . -name '*.ttf' -exec install -m 444 -Dt $dest '{}' +
  63         ''
  64       else
  65         ''
  66           for font in $fonts; do
  67             find . \( -name "$font-*.ttf" -o -name "$font[*.ttf" -o -name "$font.ttf" \) -exec install -m 444 -Dt $dest '{}' +
  68           done
  69         ''
  70     );
  71
  72   meta = with lib; {
  73     homepage = "https://fonts.google.com";
  74     description = "Font files available from Google Fonts";
  75     license = with licenses; [
  76       asl20
  77       ofl
  78       ufl
  79     ];
  80     platforms = platforms.all;
  81     hydraPlatforms = [ ];
  82     maintainers = with maintainers; [ manveru ];
  83     sourceProvenance = [ sourceTypes.binaryBytecode ];
  84   };
  85 }