pkgs/by-name/gr/grafana-image-renderer/package.nix

   1 {
   2   lib,
   3   mkYarnPackage,
   4   fetchFromGitHub,
   5   fetchYarnDeps,
   6   nodejs,
   7   runtimeShell,
   8 }:
   9
  10 # Notes for the upgrade:
  11 # * Download the tarball of the new version to use.
  12 # * Replace new `package.json` here.
  13 # * Update `version`+`hash` and rebuild.
  14
  15 mkYarnPackage rec {
  16   pname = "grafana-image-renderer";
  17   version = "3.12.0";
  18
  19   src = fetchFromGitHub {
  20     owner = "grafana";
  21     repo = "grafana-image-renderer";
  22     rev = "v${version}";
  23     hash = "sha256-iTWkr7mruGda7CVz0L6puHeObnogXHfqjF9KAY+ExJg=";
  24   };
  25
  26   offlineCache = fetchYarnDeps {
  27     yarnLock = src + "/yarn.lock";
  28     hash = "sha256-h4i27yNnVU+h5/oboAq6S4+dqjkvJ6TFqtljM3ffgTI=";
  29   };
  30
  31   packageJSON = ./package.json;
  32
  33   buildPhase = ''
  34     runHook preBuild
  35
  36     pushd deps/renderer
  37     yarn run build
  38     popd
  39
  40     runHook postBuild
  41   '';
  42
  43   dontInstall = true;
  44
  45   distPhase = ''
  46     runHook preDist
  47
  48     shopt -s extglob
  49
  50     pushd deps/renderer
  51     install_path="$out/libexec/grafana-image-renderer"
  52     mkdir -p $install_path
  53     cp -R ../../node_modules $install_path
  54     cp -R ./!(node_modules) $install_path
  55     popd
  56
  57     mkdir -p $out/bin
  58     cat >$out/bin/grafana-image-renderer <<EOF
  59     #! ${runtimeShell}
  60     ${nodejs}/bin/node $install_path/build/app.js \$@
  61     EOF
  62     chmod +x $out/bin/grafana-image-renderer
  63
  64     runHook postDist
  65   '';
  66
  67   meta = with lib; {
  68     homepage = "https://github.com/grafana/grafana-image-renderer";
  69     description = "Grafana backend plugin that handles rendering of panels & dashboards to PNGs using headless browser (Chromium/Chrome)";
  70     mainProgram = "grafana-image-renderer";
  71     license = licenses.asl20;
  72     maintainers = with maintainers; [ ma27 ];
  73     platforms = platforms.all;
  74   };
  75 }