pkgs/by-name/gt/gtkclipblock/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   meson,
   6   cmake,
   7   ninja,
   8   pkg-config,
   9   gtk2,
  10   gtk3,
  11   gtk4,
  12 }:
  13
  14 let
  15   distorm-src = fetchFromGitHub {
  16     owner = "gdabah";
  17     repo = "distorm";
  18     rev = "3.5.2b";
  19     hash = "sha256-2ftEV3TMS3HT7f96k+Pwt3Mm31fVEXcHpcbbz05jycU=";
  20   };
  21   pname = "gtkclipblock";
  22   version = "0.2.2";
  23
  24   src = fetchFromGitHub {
  25     owner = "notpeelz";
  26     repo = "gtkclipblock";
  27     rev = "v${version}";
  28     hash = "sha256-ok/D7M0KekN8zf8AzhcOLtedbYVRHHv3m9zEHsJfcPM=";
  29     fetchSubmodules = true;
  30   };
  31 in
  32 stdenv.mkDerivation {
  33   inherit pname version src;
  34
  35   nativeBuildInputs = [
  36     meson
  37     cmake
  38     ninja
  39     pkg-config
  40   ];
  41
  42   buildInputs = [
  43     gtk2
  44     gtk3
  45     gtk4
  46   ];
  47
  48   postPatch = ''
  49     substituteInPlace subprojects/funchook-helper/subprojects/funchook/CMakeLists.txt \
  50       --replace "GIT_REPOSITORY https://github.com/gdabah/distorm.git" "SOURCE_DIR ${distorm-src}"
  51   '';
  52
  53   dontUseCmakeConfigure = true;
  54
  55   meta = with lib; {
  56     description = "LD_PRELOAD hack to prevent GTK programs from interacting with the primary clipboard";
  57     license = licenses.lgpl3Only;
  58     maintainers = with maintainers; [ uartman ];
  59     platforms = [ "x86_64-linux" ];
  60   };
  61 }