pkgs/by-name/gu/guile-sdl/package.nix

   1 {
   2   lib,
   3   SDL,
   4   SDL_image,
   5   SDL_mixer,
   6   SDL_ttf,
   7   buildEnv,
   8   fetchurl,
   9   guile,
  10   lzip,
  11   pkg-config,
  12   stdenv,
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "guile-sdl";
  17   version = "0.6.1";
  18
  19   src = fetchurl {
  20     url = "mirror://gnu/guile-sdl/guile-sdl-${finalAttrs.version}.tar.lz";
  21     hash = "sha256-/9sTTvntkRXck3FoRalROjqUQC8hkePtLTnHNZotKOE=";
  22   };
  23
  24   nativeBuildInputs = [
  25     SDL
  26     guile
  27     lzip
  28     pkg-config
  29   ];
  30
  31   configureFlags = [
  32     (lib.enableFeature (!stdenv.hostPlatform.isDarwin) "sdltest")
  33   ];
  34
  35   buildInputs = [
  36     (lib.getDev SDL)
  37     (lib.getDev SDL_image)
  38     (lib.getDev SDL_mixer)
  39     (lib.getDev SDL_ttf)
  40     guile
  41   ];
  42
  43   makeFlags =
  44     let
  45       sdl-env = buildEnv {
  46         name = "sdl-env";
  47         paths = finalAttrs.buildInputs;
  48       };
  49     in
  50     [
  51       "SDLMINUSI=-I${sdl-env}/include/SDL"
  52     ];
  53
  54   strictDeps = true;
  55
  56   meta = {
  57     # clang-16: error: unsupported option '--visibility=hidden'; did you mean '-fvisibility=hidden'
  58     broken = stdenv.hostPlatform.isDarwin;
  59     homepage = "https://www.gnu.org/software/guile-sdl/";
  60     description = "Guile bindings for SDL";
  61     license = lib.licenses.gpl3Plus;
  62     maintainers = lib.teams.sdl.members
  63                   ++ (with lib.maintainers; [ ]);
  64     inherit (guile.meta) platforms;
  65   };
  66 })