pkgs/by-name/ha/hawkthorne-journey/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   love,
   6   lua,
   7   zip,
   8   makeWrapper,
   9   makeDesktopItem,
  10   copyDesktopItems,
  11   tmx2lua,
  12 }:
  13
  14 stdenv.mkDerivation (finalAttrs: {
  15   pname = "hawkthorne-journey";
  16   version = "1.1.0";
  17
  18   src = fetchFromGitHub {
  19     owner = "hawkthorne";
  20     repo = "hawkthorne-journey";
  21     tag = "v${finalAttrs.version}";
  22     hash = "sha256-RhxI2ChkFCBu2FaW2/eHT1KTTjKP++aHDktT+qQ5ooQ=";
  23   };
  24
  25   nativeBuildInputs = [
  26     zip
  27     makeWrapper
  28     copyDesktopItems
  29   ];
  30
  31   buildInputs = [
  32     love
  33     lua
  34     tmx2lua
  35   ];
  36
  37   buildPhase = ''
  38     runHook preBuild
  39
  40     # Convert TMX maps to Lua
  41     for tmxfile in src/maps/*.tmx; do
  42       tmx2lua "$tmxfile"
  43     done
  44
  45     # Create the .love file
  46     cd src
  47     zip -X -r ../hawkthorne.love . \
  48       -x ".*" \
  49       -x "*.DS_Store" \
  50       -x "psds/*" \
  51       -x "test/*" \
  52       -x "*.tmx" \
  53       -x "maps/test-level.lua" \
  54       -x "*/full_soundtrack.ogg" \
  55       -x "*.bak"
  56
  57       runHook postBuild
  58   '';
  59
  60   installPhase = ''
  61     runHook preInstall
  62
  63     cd ..
  64     mkdir -p $out/share/games/hawkthorne
  65     cp hawkthorne.love $out/share/games/hawkthorne/
  66
  67     mkdir -p $out/bin
  68     makeWrapper ${love}/bin/love $out/bin/hawkthorne \
  69       --add-flags "$out/share/games/hawkthorne/hawkthorne.love"
  70
  71     runHook postInstall
  72   '';
  73
  74   desktopItems = [
  75     (makeDesktopItem {
  76       name = "hawkthorne";
  77       exec = "hawkthorne";
  78       icon = "hawkthorne";
  79       desktopName = "Journey to the Center of Hawkthorne";
  80       genericName = "Platform Game";
  81       categories = [
  82         "Game"
  83         "ArcadeGame"
  84       ];
  85     })
  86   ];
  87
  88   meta = {
  89     description = "Journey to the Center of Hawkthorne - Community Fan Game";
  90     homepage = "https://projecthawkthorne.com";
  91     changelog = "https://github.com/hawkthorne/hawkthorne-journey/releases/tag/v${finalAttrs.version}";
  92     license = lib.licenses.mit;
  93     maintainers = with lib.maintainers; [ liberodark ];
  94     mainProgram = "hawkthorne";
  95   };
  96 })