pkgs/by-name/he/hentai-at-home/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchzip,
   5   jdk_headless,
   6   makeWrapper,
   7   buildPackages,
   8   javaOpts ? "-XX:+UseZGC",
   9 }:
  10 stdenvNoCC.mkDerivation (finalAttrs: {
  11   pname = "hentai-at-home";
  12   version = "1.6.4";
  13
  14   src = fetchzip {
  15     url = "https://repo.e-hentai.org/hath/HentaiAtHome_${finalAttrs.version}_src.zip";
  16     hash = "sha512-dcHWZiU0ySLlEhZeK1n2T/dyO6Wk9eS7CpZRSfzY3KvHrPBthQnaFrarSopPXJan1+zWROu1pEff1WSr5+HO4Q==";
  17     stripRoot = false;
  18   };
  19
  20   nativeBuildInputs = [
  21     jdk_headless
  22     makeWrapper
  23   ];
  24
  25   LANG = "en_US.UTF-8";
  26   LOCALE_ARCHIVE = lib.optionalString (
  27     stdenvNoCC.buildPlatform.libc == "glibc"
  28   ) "${buildPackages.glibcLocales}/lib/locale/locale-archive";
  29
  30   makeFlags = [ "all" ];
  31   enableParallelBuilding = false;
  32
  33   installPhase = ''
  34     runHook preInstall
  35
  36     mkdir -p $out/share/java
  37     cp build/HentaiAtHome.jar $out/share/java
  38
  39     mkdir -p $out/bin
  40     makeWrapper ${jdk_headless}/bin/java $out/bin/HentaiAtHome \
  41       --add-flags "${javaOpts} -jar $out/share/java/HentaiAtHome.jar"
  42
  43     runHook postInstall
  44   '';
  45
  46   doInstallCheck = true;
  47   installCheckPhase = ''
  48     runHook preInstallCheck
  49
  50     pushd $(mktemp -d)
  51     $out/bin/HentaiAtHome
  52     popd
  53
  54     runHook postInstallCheck
  55   '';
  56
  57   strictDeps = true;
  58
  59   meta = with lib; {
  60     homepage = "https://ehwiki.org/wiki/Hentai@Home";
  61     description = "Open-source P2P gallery distribution system which reduces the load on the E-Hentai Galleries";
  62     license = licenses.gpl3;
  63     maintainers = with maintainers; [ terrorjack ];
  64     mainProgram = "HentaiAtHome";
  65     platforms = jdk_headless.meta.platforms;
  66   };
  67 })