pkgs/by-name/ip/ipvsadm/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   pkg-config,
   6   libnl,
   7   popt,
   8   gnugrep,
   9 }:
  10
  11 stdenv.mkDerivation rec {
  12   pname = "ipvsadm";
  13   version = "1.31";
  14
  15   src = fetchurl {
  16     url = "mirror://kernel/linux/utils/kernel/ipvsadm/${pname}-${version}.tar.xz";
  17     sha256 = "1nyzpv1hx75k9lh0vfxfhc0p2fpqaqb38xpvs8sn88m1nljmw2hs";
  18   };
  19
  20   postPatch = ''
  21     substituteInPlace Makefile --replace "-lnl" "$(pkg-config --libs libnl-genl-3.0)"
  22   '';
  23
  24   nativeBuildInputs = [ pkg-config ];
  25   buildInputs = [
  26     libnl
  27     popt
  28   ];
  29
  30   # Disable parallel build, errors:
  31   #  *** No rule to make target 'libipvs/libipvs.a', needed by 'ipvsadm'.  Stop.
  32   enableParallelBuilding = false;
  33
  34   preBuild = ''
  35     makeFlagsArray+=(
  36       INCLUDE=$(pkg-config --cflags libnl-genl-3.0)
  37       BUILD_ROOT=$out
  38       MANDIR=share/man
  39     )
  40   '';
  41
  42   postInstall = ''
  43     sed -i -e "s|^PATH=.*|PATH=$out/bin:${gnugrep}/bin|" $out/sbin/ipvsadm-{restore,save}
  44   '';
  45
  46   meta = with lib; {
  47     description = "Linux Virtual Server support programs";
  48     homepage = "http://www.linuxvirtualserver.org/software/ipvs.html";
  49     license = licenses.gpl2Plus;
  50     platforms = platforms.linux;
  51   };
  52 }