pkgs/by-name/je/jetbrains-toolbox/package.nix

   1 { stdenv
   2 , lib
   3 , fetchzip
   4 , copyDesktopItems
   5 , makeWrapper
   6 , runCommand
   7 , appimageTools
   8 , icu
   9 , genericUpdater
  10 , writeShellScript
  11 }:
  12 let
  13   pname = "jetbrains-toolbox";
  14   version = "2.5.1.34629";
  15
  16   src = fetchzip {
  17     url = "https://download.jetbrains.com/toolbox/jetbrains-toolbox-${version}.tar.gz";
  18     hash = "sha256-YaMlvgktoa738grHarJX2Uh5PZ7qHuASyJBcUhMssEI=";
  19     stripRoot = false;
  20   };
  21
  22   appimageContents = runCommand "${pname}-extracted"
  23     {
  24       nativeBuildInputs = [ appimageTools.appimage-exec ];
  25     }
  26     ''
  27       appimage-exec.sh -x $out ${src}/jetbrains-toolbox-${version}/jetbrains-toolbox
  28
  29       # JetBrains ship a broken desktop file. Despite registering a custom
  30       # scheme handler for jetbrains:// URLs, they never mark the command as
  31       # being suitable for passing URLs to. Ergo, the handler never receives
  32       # its payload. This causes various things to break, including login.
  33       # Reported upstream at: https://youtrack.jetbrains.com/issue/TBX-11478/
  34       sed -Ei '/^Exec=/s/( %U)?$/ %U/' $out/jetbrains-toolbox.desktop
  35     '';
  36
  37   appimage = appimageTools.wrapAppImage {
  38     inherit pname version;
  39     src = appimageContents;
  40   };
  41 in
  42 stdenv.mkDerivation {
  43   inherit pname version src appimage;
  44
  45   nativeBuildInputs = [ makeWrapper copyDesktopItems ];
  46
  47   installPhase = ''
  48     runHook preInstall
  49
  50     install -Dm644 ${appimageContents}/.DirIcon $out/share/icons/hicolor/scalable/apps/jetbrains-toolbox.svg
  51     makeWrapper ${appimage}/bin/jetbrains-toolbox $out/bin/jetbrains-toolbox \
  52       --append-flags "--update-failed" \
  53       --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [icu]}
  54
  55     runHook postInstall
  56   '';
  57
  58   desktopItems = [ "${appimageContents}/jetbrains-toolbox.desktop" ];
  59
  60   # Disabling the tests, this seems to be very difficult to test this app.
  61   doCheck = false;
  62
  63   passthru.updateScript = genericUpdater {
  64     versionLister = writeShellScript "jetbrains-toolbox-versionLister" ''
  65       curl -Ls 'https://data.services.jetbrains.com/products?code=TBA&release.type=release' \
  66         | jq -r '.[] | .releases | flatten[] | .build'
  67     '';
  68   };
  69
  70   meta = with lib; {
  71     description = "Jetbrains Toolbox";
  72     homepage = "https://jetbrains.com/";
  73     license = licenses.unfree;
  74     maintainers = with maintainers; [ AnatolyPopov ];
  75     platforms = [ "x86_64-linux" ];
  76     mainProgram = "jetbrains-toolbox";
  77   };
  78 }