pkgs/by-name/ke/kent/package.nix

   1 { lib, stdenv
   2 , libpng
   3 , libuuid
   4 , zlib
   5 , bzip2
   6 , xz
   7 , openssl
   8 , curl
   9 , libmysqlclient
  10 , bash
  11 , fetchFromGitHub
  12 , which
  13 }:
  14 stdenv.mkDerivation rec {
  15   pname = "kent";
  16   version = "468";
  17
  18   src = fetchFromGitHub {
  19     owner = "ucscGenomeBrowser";
  20     repo = pname;
  21     rev = "v${version}_base";
  22     hash = "sha256-OM/noraW2X8WV5wqWEFiI5/JPOBmsp0fTeDdcZoXxAA=";
  23   };
  24
  25   buildInputs = [ libpng libuuid zlib bzip2 xz openssl curl libmysqlclient ];
  26
  27   postPatch = ''
  28     substituteInPlace ./src/checkUmask.sh \
  29       --replace "/bin/bash" "${bash}/bin/bash"
  30
  31     substituteInPlace ./src/hg/sqlEnvTest.sh \
  32       --replace "which mysql_config" "${which}/bin/which ${libmysqlclient}/bin/mysql_config"
  33   '';
  34
  35   buildPhase = ''
  36     runHook preBuild
  37
  38     export MACHTYPE=$(uname -m)
  39     export CFLAGS="-fPIC"
  40     export MYSQLINC=$(mysql_config --include | sed -e 's/^-I//g')
  41     export MYSQLLIBS=$(mysql_config --libs)
  42     export HOME=$TMPDIR
  43     export DESTBINDIR=$HOME/bin
  44
  45     mkdir -p $HOME/lib $HOME/bin/x86_64
  46
  47     cd ./src
  48     chmod +x ./checkUmask.sh
  49     ./checkUmask.sh
  50
  51     make libs
  52     cd jkOwnLib
  53     make
  54
  55     cp ../lib/x86_64/jkOwnLib.a $HOME/lib
  56     cp ../lib/x86_64/jkweb.a $HOME/lib
  57     cp -r ../inc  $HOME/
  58
  59     cd ../utils
  60     make
  61
  62     runHook postBuild
  63   '';
  64
  65   installPhase = ''
  66     runHook preInstall
  67
  68     mkdir -p $out/bin $out/lib $out/inc
  69     cp $HOME/lib/jkOwnLib.a $out/lib
  70     cp $HOME/lib/jkweb.a $out/lib
  71     cp $HOME/bin/x86_64/* $out/bin
  72     cp -r $HOME/inc/* $out/inc/
  73
  74     runHook postInstall
  75   '';
  76
  77   meta = with lib; {
  78     description = "UCSC Genome Bioinformatics Group's suite of biological analysis tools, i.e. the kent utilities";
  79     homepage = "http://genome.ucsc.edu";
  80     changelog = "https://github.com/ucscGenomeBrowser/kent/releases/tag/v${version}_base";
  81     license = licenses.unfree;
  82     maintainers = with maintainers; [ scalavision ];
  83     platforms = platforms.linux;
  84   };
  85 }