pkgs/by-name/li/libcardiacarrest/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   pkg-config,
   6   glib,
   7   libpulseaudio,
   8 }:
   9
  10 stdenv.mkDerivation rec {
  11   pname = "libcardiacarrest";
  12   version = "12.2.8"; # <PA API version>.<version>
  13
  14   src = fetchFromGitHub {
  15     owner = "oxij";
  16     repo = "libcardiacarrest";
  17     rev = "d89639f5b2d298cf74af26880f5ebf50e645166d";
  18     sha256 = "0vrigwcw3g8zknqyznv6y3437ahn1w00gv3d303smmygr0p8bd94";
  19   };
  20
  21   outputs = [
  22     "out"
  23     "dev"
  24   ];
  25
  26   nativeBuildInputs = [ pkg-config ];
  27
  28   buildInputs = [ glib ];
  29
  30   makeFlags = [ "PREFIX=$(out)" ];
  31
  32   postInstall = ''
  33     moveToOutput $out/include $dev
  34     moveToOutput $out/lib/pkgconfig $dev
  35     moveToOutput $out/lib/cmake $dev
  36   '';
  37
  38   meta =
  39     with lib;
  40     src.meta
  41     // {
  42       description = "Trivial implementation of libpulse PulseAudio library API";
  43       longDescription = ''
  44         libcardiacarrest is a trivial implementation of libpulse
  45         PulseAudio library API that unconditionally (but gracefully)
  46         fails to connect to the PulseAudio daemon and does nothing else.
  47
  48         apulse and pressureaudio (which uses apulse internally) are an
  49         inspiration for this but unlike those two projects
  50         libcardiacarrest is not an emulation layer, all it does is it
  51         gracefully fails to provide the requested PulseAudio service
  52         hoping the application would try something else (e.g. ALSA or
  53         JACK).
  54       '';
  55       license = libpulseaudio.meta.license; # "same as PA headers"
  56       maintainers = [ maintainers.oxij ]; # also the author
  57     };
  58
  59 }