pkgs/by-name/li/libdatrie/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   autoreconfHook,
   6   autoconf-archive,
   7   installShellFiles,
   8   libiconv,
   9 }:
  10
  11 stdenv.mkDerivation rec {
  12
  13   pname = "libdatrie";
  14   version = "2019-12-20";
  15
  16   outputs = [
  17     "bin"
  18     "out"
  19     "lib"
  20     "dev"
  21   ];
  22
  23   src = fetchFromGitHub {
  24     owner = "tlwg";
  25     repo = "libdatrie";
  26     rev = "d1db08ac1c76f54ba23d63665437473788c999f3";
  27     sha256 = "03dc363259iyiidrgadzc7i03mmfdj8h78j82vk6z53w6fxq5zxc";
  28   };
  29
  30   nativeBuildInputs = [
  31     autoreconfHook
  32     autoconf-archive
  33     installShellFiles
  34   ];
  35
  36   buildInputs = [ libiconv ];
  37
  38   preAutoreconf =
  39     let
  40       reports = "https://github.com/tlwg/libdatrie/issues";
  41     in
  42     ''
  43       sed -i -e "/AC_INIT/,+3d" configure.ac
  44       sed -i "5iAC_INIT(${pname},${version},[${reports}])" configure.ac
  45     '';
  46
  47   postInstall = ''
  48     installManPage man/trietool.1
  49   '';
  50
  51   meta = with lib; {
  52     homepage = "https://linux.thai.net/~thep/datrie/datrie.html";
  53     description = "This is an implementation of double-array structure for representing trie";
  54     license = licenses.lgpl21Plus;
  55     platforms = platforms.unix;
  56     maintainers = [ ];
  57     pkgConfigModules = [ "datrie-0.2" ];
  58   };
  59 }