pkgs/by-name/li/libfido2/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   cmake,
   6   pkg-config,
   7   hidapi,
   8   libcbor,
   9   openssl,
  10   udev,
  11   zlib,
  12   withPcsclite ? true,
  13   pcsclite,
  14 }:
  15
  16 stdenv.mkDerivation rec {
  17   pname = "libfido2";
  18   version = "1.15.0";
  19
  20   # releases on https://developers.yubico.com/libfido2/Releases/ are signed
  21   src = fetchurl {
  22     url = "https://developers.yubico.com/${pname}/Releases/${pname}-${version}.tar.gz";
  23     hash = "sha256-q6qxMY0h0mLs5Bb7inEy+pN0vaifb6UrhqmKL1cSth4=";
  24   };
  25
  26   nativeBuildInputs = [
  27     cmake
  28     pkg-config
  29   ];
  30
  31   buildInputs =
  32     [
  33       libcbor
  34       zlib
  35     ]
  36     ++ lib.optionals stdenv.hostPlatform.isDarwin [ hidapi ]
  37     ++ lib.optionals stdenv.hostPlatform.isLinux [ udev ]
  38     ++ lib.optionals (stdenv.hostPlatform.isLinux && withPcsclite) [ pcsclite ];
  39
  40   propagatedBuildInputs = [ openssl ];
  41
  42   outputs = [
  43     "out"
  44     "dev"
  45     "man"
  46   ];
  47
  48   cmakeFlags =
  49     [
  50       "-DUDEV_RULES_DIR=${placeholder "out"}/etc/udev/rules.d"
  51       "-DCMAKE_INSTALL_LIBDIR=lib"
  52     ]
  53     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  54       "-DUSE_HIDAPI=1"
  55     ]
  56     ++ lib.optionals stdenv.hostPlatform.isLinux [
  57       "-DNFC_LINUX=1"
  58     ]
  59     ++ lib.optionals (stdenv.hostPlatform.isLinux && withPcsclite) [
  60       "-DUSE_PCSC=1"
  61     ];
  62
  63   # causes possible redefinition of _FORTIFY_SOURCE?
  64   hardeningDisable = [ "fortify3" ];
  65
  66   meta = with lib; {
  67     description = ''
  68       Provides library functionality for FIDO 2.0, including communication with a device over USB.
  69     '';
  70     homepage = "https://github.com/Yubico/libfido2";
  71     license = licenses.bsd2;
  72     maintainers = with maintainers; [ prusnak ];
  73     platforms = platforms.unix;
  74   };
  75 }