pkgs/by-name/li/libfprint-tod/package.nix

   1 {
   2   lib,
   3   libfprint,
   4   fetchFromGitLab,
   5 }:
   6
   7 # for the curious, "tod" means "Touch OEM Drivers" meaning it can load
   8 # external .so's.
   9 libfprint.overrideAttrs (
  10   {
  11     postPatch ? "",
  12     mesonFlags ? [ ],
  13     ...
  14   }:
  15   let
  16     version = "1.90.7+git20210222+tod1";
  17   in
  18   {
  19     pname = "libfprint-tod";
  20     inherit version;
  21
  22     src = fetchFromGitLab {
  23       domain = "gitlab.freedesktop.org";
  24       owner = "3v1n0";
  25       repo = "libfprint";
  26       rev = "v${version}";
  27       sha256 = "0cj7iy5799pchyzqqncpkhibkq012g3bdpn18pfb19nm43svhn4j";
  28     };
  29
  30     mesonFlags = [
  31       # Include virtual drivers for fprintd tests
  32       "-Ddrivers=all"
  33       "-Dudev_hwdb_dir=${placeholder "out"}/lib/udev/hwdb.d"
  34     ];
  35
  36     postPatch = ''
  37       ${postPatch}
  38       patchShebangs ./tests/*.py ./tests/*.sh
  39     '';
  40
  41     meta = with lib; {
  42       homepage = "https://gitlab.freedesktop.org/3v1n0/libfprint";
  43       description = "Library designed to make it easy to add support for consumer fingerprint readers, with support for loaded drivers";
  44       license = licenses.lgpl21;
  45       platforms = platforms.linux;
  46       maintainers = with maintainers; [ grahamc ];
  47     };
  48   }
  49 )