pkgs/by-name/li/libhugetlbfs/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchurl,
   5   autoreconfHook,
   6 }:
   7
   8 stdenv.mkDerivation rec {
   9   pname = "libhugetlbfs";
  10   version = "2.24";
  11
  12   src = fetchurl {
  13     url = "https://github.com/libhugetlbfs/libhugetlbfs/releases/download/${version}/libhugetlbfs-${version}.tar.gz";
  14     hash = "sha256-1QHfqRyOrREGlno9OCnyunOMP6wKZcs1jtKrOHDdxe8=";
  15   };
  16
  17   outputs = [
  18     "bin"
  19     "dev"
  20     "man"
  21     "doc"
  22     "lib"
  23     "out"
  24   ];
  25
  26   nativeBuildInputs = [ autoreconfHook ];
  27
  28   postConfigure = ''
  29     patchShebangs ld.hugetlbfs
  30   '';
  31
  32   enableParallelBuilding = true;
  33   makeFlags =
  34     [
  35       "BUILDTYPE=NATIVEONLY"
  36       "PREFIX=$(out)"
  37       "HEADERDIR=$(dev)/include"
  38       "LIBDIR32=$(lib)/$(LIB32)"
  39       "LIBDIR64=$(lib)/$(LIB64)"
  40       "EXEDIR=$(bin)/bin"
  41       "DOCDIR=$(doc)/share/doc/libhugetlbfs"
  42       "MANDIR=$(man)/share/man"
  43     ]
  44     ++ lib.optionals (stdenv.buildPlatform.system != stdenv.hostPlatform.system) [
  45       # The ARCH logic defaults to querying `uname`, which will return build platform arch
  46       "ARCH=${stdenv.hostPlatform.uname.processor}"
  47     ];
  48
  49   # Default target builds tests as well, and the tests want a static
  50   # libc.
  51   buildFlags = [
  52     "libs"
  53     "tools"
  54   ];
  55   installTargets = [
  56     "install"
  57     "install-docs"
  58   ];
  59
  60   meta = with lib; {
  61     homepage = "https://github.com/libhugetlbfs/libhugetlbfs";
  62     changelog = "https://github.com/libhugetlbfs/libhugetlbfs/blob/${version}/NEWS";
  63     description = "library and utilities for Linux hugepages";
  64     maintainers = with maintainers; [ qyliss ];
  65     license = licenses.lgpl21Plus;
  66     platforms = platforms.linux;
  67     badPlatforms = flatten [
  68       systems.inspect.platformPatterns.isStatic
  69       systems.inspect.patterns.isMusl
  70     ];
  71   };
  72 }