pkgs/by-name/li/libmanette/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   ninja,
   6   meson,
   7   mesonEmulatorHook,
   8   pkg-config,
   9   vala,
  10   gobject-introspection,
  11   buildPackages,
  12   withIntrospection ?
  13     lib.meta.availableOn stdenv.hostPlatform gobject-introspection
  14     && stdenv.hostPlatform.emulatorAvailable buildPackages,
  15   gtk-doc,
  16   docbook-xsl-nons,
  17   docbook_xml_dtd_43,
  18   glib,
  19   libgudev,
  20   libevdev,
  21   gnome,
  22 }:
  23
  24 stdenv.mkDerivation rec {
  25   pname = "libmanette";
  26   version = "0.2.9";
  27
  28   outputs = [
  29     "out"
  30     "dev"
  31   ] ++ lib.optional withIntrospection "devdoc";
  32
  33   src = fetchurl {
  34     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  35     hash = "sha256-KTZr5UUvYKdMZfxk/+LXTt3U5uaCTCzvpWekO9kraI8=";
  36   };
  37
  38   nativeBuildInputs =
  39     [
  40       meson
  41       ninja
  42       pkg-config
  43       glib
  44     ]
  45     ++ lib.optionals withIntrospection [
  46       vala
  47       gobject-introspection
  48       gtk-doc
  49       docbook-xsl-nons
  50       docbook_xml_dtd_43
  51     ]
  52     ++ lib.optionals (withIntrospection && !stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
  53       mesonEmulatorHook
  54     ];
  55
  56   buildInputs =
  57     [
  58       glib
  59       libevdev
  60     ]
  61     ++ lib.optionals withIntrospection [
  62       libgudev
  63     ];
  64
  65   mesonFlags = [
  66     (lib.mesonBool "doc" withIntrospection)
  67     (lib.mesonEnable "gudev" withIntrospection)
  68     (lib.mesonBool "introspection" withIntrospection)
  69     (lib.mesonBool "vapi" withIntrospection)
  70   ];
  71
  72   doCheck = true;
  73
  74   passthru = {
  75     updateScript = gnome.updateScript {
  76       packageName = pname;
  77       versionPolicy = "odd-unstable";
  78     };
  79   };
  80
  81   meta = with lib; {
  82     description = "Simple GObject game controller library";
  83     mainProgram = "manette-test";
  84     homepage = "https://gnome.pages.gitlab.gnome.org/libmanette/";
  85     license = licenses.lgpl21Plus;
  86     maintainers = teams.gnome.members;
  87     platforms = platforms.unix;
  88   };
  89 }