pkgs/by-name/li/libmediainfo/package.nix

   1 { lib, stdenv, fetchurl, autoreconfHook, pkg-config, libzen, zlib
   2
   3 # Whether to enable resolving URLs via libcurl
   4 , curlSupport ? true, curl
   5 }:
   6
   7 stdenv.mkDerivation rec {
   8   pname = "libmediainfo";
   9   version = "24.12";
  10
  11   src = fetchurl {
  12     url = "https://mediaarea.net/download/source/libmediainfo/${version}/libmediainfo_${version}.tar.xz";
  13     hash = "sha256-H0mGIH913rKQkV5r8LM+PkVXdDBd0mb/6Jl8AarWWyc=";
  14   };
  15
  16   nativeBuildInputs = [ autoreconfHook pkg-config ];
  17   buildInputs = [ zlib ] ++ lib.optionals curlSupport [ curl ];
  18   propagatedBuildInputs = [ libzen ];
  19
  20   sourceRoot = "MediaInfoLib/Project/GNU/Library";
  21
  22   postPatch = lib.optionalString (stdenv.cc.targetPrefix != "") ''
  23     substituteInPlace configure.ac \
  24       --replace "pkg-config " "${stdenv.cc.targetPrefix}pkg-config "
  25   '';
  26
  27   configureFlags = [
  28     "--enable-shared"
  29   ] ++ lib.optionals curlSupport [
  30     "--with-libcurl"
  31   ];
  32
  33   enableParallelBuilding = true;
  34
  35   postInstall = ''
  36     install -vD -m 644 libmediainfo.pc "$out/lib/pkgconfig/libmediainfo.pc"
  37   '';
  38
  39   meta = with lib; {
  40     description = "Shared library for mediainfo";
  41     homepage = "https://mediaarea.net/";
  42     changelog = "https://mediaarea.net/MediaInfo/ChangeLog";
  43     license = licenses.bsd2;
  44     platforms = platforms.unix;
  45     maintainers = [ maintainers.devhell ];
  46   };
  47 }