pkgs/by-name/li/libmtp/package.nix

   1 {
   2   stdenv,
   3   autoconf,
   4   automake,
   5   fetchFromGitHub,
   6   fetchpatch,
   7   gettext,
   8   lib,
   9   libiconv,
  10   libtool,
  11   libusb1,
  12   pkg-config,
  13   buildPackages,
  14 }:
  15
  16 stdenv.mkDerivation rec {
  17   pname = "libmtp";
  18   version = "1.1.21";
  19
  20   src = fetchFromGitHub {
  21     owner = "libmtp";
  22     repo = "libmtp";
  23     rev = "libmtp-${builtins.replaceStrings [ "." ] [ "-" ] version}";
  24     sha256 = "sha256-m9QFVD8udQ3SdGwn276BnIKqGeATA5QuokOK29Ykc1k=";
  25   };
  26
  27   patches = [
  28     # Backport cross fix.
  29     (fetchpatch {
  30       url = "https://github.com/libmtp/libmtp/commit/467fa26e6b14c0884b15cf6d191de97e5513fe05.patch";
  31       sha256 = "2DrRrdcguJ9su4LxtT6YOjer8gUTxIoHVpk+6M9P4cg=";
  32     })
  33   ];
  34
  35   outputs = [
  36     "bin"
  37     "dev"
  38     "out"
  39   ];
  40
  41   nativeBuildInputs = [
  42     autoconf
  43     automake
  44     gettext
  45     libtool
  46     pkg-config
  47   ];
  48
  49   buildInputs = [ libiconv ];
  50
  51   propagatedBuildInputs = [ libusb1 ];
  52
  53   preConfigure = "NOCONFIGURE=1 ./autogen.sh";
  54
  55   configureFlags = [ "--with-udev=${placeholder "out"}/lib/udev" ];
  56
  57   configurePlatforms = [
  58     "build"
  59     "host"
  60   ];
  61
  62   makeFlags =
  63     lib.optionals (stdenv.hostPlatform.isLinux && !stdenv.buildPlatform.canExecute stdenv.hostPlatform)
  64       [
  65         "MTP_HOTPLUG=${buildPackages.libmtp}/bin/mtp-hotplug"
  66       ];
  67
  68   enableParallelBuilding = true;
  69
  70   meta = with lib; {
  71     homepage = "https://github.com/libmtp/libmtp";
  72     description = "Implementation of Microsoft's Media Transfer Protocol";
  73     longDescription = ''
  74       libmtp is an implementation of Microsoft's Media Transfer Protocol (MTP)
  75       in the form of a library suitable primarily for POSIX compliant operating
  76       systems. We implement MTP Basic, the stuff proposed for standardization.
  77     '';
  78     platforms = platforms.unix;
  79     license = licenses.lgpl21;
  80     maintainers = with maintainers; [ lovesegfault ];
  81   };
  82 }