pkgs/by-name/li/liboping/package.nix

   1 {
   2   stdenv,
   3   fetchurl,
   4   fetchpatch,
   5   ncurses ? null,
   6   perl ? null,
   7   lib,
   8 }:
   9
  10 stdenv.mkDerivation rec {
  11   pname = "liboping";
  12   version = "1.10.0";
  13
  14   src = fetchurl {
  15     url = "https://noping.cc/files/${pname}-${version}.tar.bz2";
  16     sha256 = "1n2wkmvw6n80ybdwkjq8ka43z2x8mvxq49byv61b52iyz69slf7b";
  17   };
  18
  19   patches = [
  20     # Add support for ncurses-6.3. A backport of patch pending upstream
  21     # inclusion: https://github.com/octo/liboping/pull/61
  22     ./ncurses-6.3.patch
  23
  24     # Pull pending fix for format arguments mismatch:
  25     #  https://github.com/octo/liboping/pull/60
  26     (fetchpatch {
  27       name = "format-args.patch";
  28       url = "https://github.com/octo/liboping/commit/7a50e33f2a686564aa43e4920141e6f64e042df1.patch";
  29       sha256 = "118fl3k84m3iqwfp49g5qil4lw1gcznzmyxnfna0h7za2nm50cxw";
  30     })
  31   ];
  32
  33   env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isGNU "-Wno-error=format-truncation";
  34
  35   buildInputs = [
  36     ncurses
  37     perl
  38   ];
  39
  40   configureFlags = lib.optional (perl == null) "--with-perl-bindings=no";
  41
  42   meta = with lib; {
  43     description = "C library to generate ICMP echo requests (a.k.a. ping packets)";
  44     longDescription = ''
  45       liboping is a C library to generate ICMP echo requests, better known as
  46       "ping packets". It is intended for use in network monitoring applications
  47       or applications that would otherwise need to fork ping(1) frequently.
  48       Included is a sample application, called oping, which demonstrates the
  49       library's abilities.
  50     '';
  51     homepage = "http://noping.cc/";
  52     license = licenses.lgpl21;
  53     platforms = platforms.unix;
  54     maintainers = [ maintainers.bjornfor ];
  55   };
  56 }