pkgs/by-name/li/libpsl/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   autoreconfHook,
   6   docbook_xsl,
   7   docbook_xml_dtd_43,
   8   gtk-doc,
   9   lzip,
  10   libidn2,
  11   libunistring,
  12   libxslt,
  13   pkg-config,
  14   python3,
  15   buildPackages,
  16   publicsuffix-list,
  17 }:
  18
  19 stdenv.mkDerivation rec {
  20   pname = "libpsl";
  21   version = "0.21.5";
  22
  23   src = fetchurl {
  24     url = "https://github.com/rockdaboot/libpsl/releases/download/${version}/libpsl-${version}.tar.lz";
  25     hash = "sha256-mp9qjG7bplDPnqVUdc0XLdKEhzFoBOnHMgLZdXLNOi0=";
  26   };
  27
  28   outputs =
  29     [
  30       "out"
  31       "dev"
  32     ]
  33     # bin/psl-make-dafsa brings a large runtime closure through python3
  34     ++ lib.optional (!stdenv.hostPlatform.isStatic) "bin";
  35
  36   nativeBuildInputs = [
  37     autoreconfHook
  38     docbook_xsl
  39     docbook_xml_dtd_43
  40     gtk-doc
  41     lzip
  42     pkg-config
  43     libxslt
  44   ];
  45
  46   buildInputs = [
  47     libidn2
  48     libunistring
  49     libxslt
  50   ] ++ lib.optional (
  51     !stdenv.hostPlatform.isStatic
  52     && !stdenv.hostPlatform.isWindows
  53     && (stdenv.hostPlatform.isDarwin -> stdenv.buildPlatform == stdenv.hostPlatform)
  54    ) python3;
  55
  56   propagatedBuildInputs = [
  57     publicsuffix-list
  58   ];
  59
  60   postPatch = lib.optionalString (!stdenv.hostPlatform.isStatic) ''
  61     patchShebangs src/psl-make-dafsa
  62   '';
  63
  64   preAutoreconf = ''
  65     gtkdocize
  66   '';
  67
  68   configureFlags = [
  69     # "--enable-gtk-doc"
  70     "--enable-man"
  71     "--with-psl-distfile=${publicsuffix-list}/share/publicsuffix/public_suffix_list.dat"
  72     "--with-psl-file=${publicsuffix-list}/share/publicsuffix/public_suffix_list.dat"
  73     "--with-psl-testfile=${publicsuffix-list}/share/publicsuffix/test_psl.txt"
  74     "PYTHON=${lib.getExe buildPackages.python3}"
  75   ];
  76
  77   enableParallelBuilding = true;
  78
  79   doCheck = true;
  80
  81   meta = with lib; {
  82     description = "C library for the Publix Suffix List";
  83     longDescription = ''
  84       libpsl is a C library for the Publix Suffix List (PSL). A "public suffix"
  85       is a domain name under which Internet users can directly register own
  86       names. Browsers and other web clients can use it to avoid privacy-leaking
  87       "supercookies" and "super domain" certificates, for highlighting parts of
  88       the domain in a user interface or sorting domain lists by site.
  89     '';
  90     homepage = "https://rockdaboot.github.io/libpsl/";
  91     changelog = "https://raw.githubusercontent.com/rockdaboot/libpsl/libpsl-${version}/NEWS";
  92     license = licenses.mit;
  93     maintainers = [ maintainers.c0bw3b ];
  94     mainProgram = "psl";
  95     platforms = platforms.unix ++ platforms.windows;
  96     pkgConfigModules = [ "libpsl" ];
  97   };
  98 }