pkgs/by-name/li/libstaden-read/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   autoreconfHook,
   5   fetchFromGitHub,
   6   bzip2,
   7   xz,
   8   zlib,
   9 }:
  10
  11 stdenv.mkDerivation (finalAttrs: {
  12   # Same name as the Debian library
  13   pname = "libstaden-read";
  14   version = "1.15.0";
  15
  16   src = fetchFromGitHub {
  17     owner = "jkbonfield";
  18     repo = "io_lib";
  19     rev = "io_lib-" + builtins.replaceStrings [ "." ] [ "-" ] finalAttrs.version;
  20     fetchSubmodules = true;
  21     hash = "sha256-2Dlx+MXmqar81/Xmf0oE+6lWX461EDYijiZsZf/VD28=";
  22   };
  23
  24   patches = [
  25     # Needed so that the lib can be detected
  26     ./libstaden-install-config-header.patch
  27   ];
  28
  29   buildInputs = [
  30     bzip2
  31     xz
  32     zlib
  33   ];
  34   nativeBuildInputs = [ autoreconfHook ];
  35
  36   # autoreconfHook does not descend into htscodecs folder
  37   preAutoreconf = ''
  38     pushd ./htscodecs
  39     autoreconf --install --force --verbose
  40     pushd
  41   '';
  42
  43   meta = {
  44     description = "C library for reading/writing various DNA sequence formats";
  45     homepage = "https://staden.sourceforge.net";
  46     downloadPage = "https://github.com/jkbonfield/io_lib/releases";
  47     changelog = "https://github.com/jkbonfield/io_lib/blob/${finalAttrs.src.rev}/CHANGES";
  48     license = with lib.licenses; [
  49       bsd3
  50       free
  51     ];
  52     platforms = lib.platforms.all;
  53     maintainers = [ lib.maintainers.kupac ];
  54   };
  55 })