pkgs/by-name/li/libstemmer/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   perl,
   6   buildPackages,
   7 }:
   8
   9 stdenv.mkDerivation rec {
  10   pname = "libstemmer";
  11   version = "2.2.0";
  12
  13   src = fetchFromGitHub {
  14     owner = "snowballstem";
  15     repo = "snowball";
  16     rev = "v${version}";
  17     sha256 = "sha256-qXrypwv/I+5npvGHGsHveijoui0ZnoGYhskCfLkewVE=";
  18   };
  19
  20   nativeBuildInputs = [ perl ];
  21
  22   prePatch =
  23     ''
  24       patchShebangs .
  25     ''
  26     + lib.optionalString (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
  27       substituteInPlace GNUmakefile \
  28         --replace './snowball' '${lib.getBin buildPackages.libstemmer}/bin/snowball'
  29     '';
  30
  31   makeTarget = "libstemmer.a";
  32
  33   installPhase = ''
  34     runHook preInstall
  35     install -Dt $out/lib libstemmer.a
  36     install -Dt $out/include include/libstemmer.h
  37     install -Dt $out/bin {snowball,stemwords}
  38     runHook postInstall
  39   '';
  40
  41   meta = with lib; {
  42     description = "Snowball Stemming Algorithms";
  43     homepage = "https://snowballstem.org/";
  44     license = licenses.bsd3;
  45     maintainers = with maintainers; [ fpletz ];
  46     platforms = platforms.all;
  47   };
  48 }