pkgs/by-name/li/little_boxes/package.nix

   1 {
   2   lib,
   3   rustPlatform,
   4   fetchFromGitHub,
   5   installShellFiles,
   6   testers,
   7   little_boxes,
   8 }:
   9
  10 rustPlatform.buildRustPackage rec {
  11   pname = "little_boxes";
  12   version = "1.10.0";
  13
  14   src = fetchFromGitHub {
  15     owner = "giodamelio";
  16     repo = "little_boxes";
  17     rev = version;
  18     hash = "sha256-Quh09K5meiA39ih/orJWF2WfkuZdymxub1dZvns/q3E=";
  19   };
  20
  21   cargoVendorDir = "vendor";
  22
  23   nativeBuildInputs = [ installShellFiles ];
  24
  25   postInstall = ''
  26     extrasPath=$(ls -d $releaseDir/build/little_boxes-*/out/)
  27
  28     installManPage $extrasPath/little_boxes.1
  29     installShellCompletion --bash $extrasPath/little_boxes.bash
  30     installShellCompletion --fish $extrasPath/little_boxes.fish
  31     installShellCompletion --zsh $extrasPath/_little_boxes
  32   '';
  33
  34   passthru.tests.version = testers.testVersion {
  35     package = little_boxes;
  36     command = "little_boxes --version";
  37   };
  38
  39   meta = with lib; {
  40     description = "Add boxes are input text";
  41     longDescription = ''
  42       little_boxes is a small program that takes input from stdin or a file
  43       and wraps it with box made of ACII/Unicode Box Drawing characters. There
  44       are several different charsets and you can optionally add a title
  45
  46       Example:
  47
  48       $ echo "Hello World" | little_boxes
  49       ┏━━━━━━━━━━━━━┓
  50       ┃ Hello World ┃
  51       ┗━━━━━━━━━━━━━┛
  52     '';
  53     homepage = "https://github.com/giodamelio/little_boxes";
  54     license = licenses.mit;
  55     maintainers = with maintainers; [ giodamelio ];
  56     mainProgram = "little_boxes";
  57   };
  58 }