pkgs/by-name/lv/lv2/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchurl,
   5   meson,
   6   ninja,
   7
   8   pipewire,
   9   gitUpdater,
  10 }:
  11
  12 stdenv.mkDerivation rec {
  13   pname = "lv2";
  14   version = "1.18.10";
  15
  16   outputs = [
  17     "out"
  18     "dev"
  19   ];
  20
  21   src = fetchurl {
  22     url = "https://lv2plug.in/spec/${pname}-${version}.tar.xz";
  23     hash = "sha256-eMUbzyG1Tli7Yymsy7Ta4Dsu15tSD5oB5zS9neUwlT8=";
  24   };
  25
  26   strictDeps = true;
  27
  28   nativeBuildInputs = [
  29     meson
  30     ninja
  31   ];
  32
  33   mesonFlags =
  34     [
  35       # install validators to $dev
  36       "--bindir=${placeholder "dev"}/bin"
  37
  38       # These are just example plugins. They pull in outdated gtk-2
  39       # dependency and many other things. Upstream would like to
  40       # eventually move them of the project:
  41       #   https://gitlab.com/lv2/lv2/-/issues/57#note_1096060029
  42       "-Dplugins=disabled"
  43       # Pulls in spell checkers among other things.
  44       "-Dtests=disabled"
  45       # Avoid heavyweight python dependencies.
  46       "-Ddocs=disabled"
  47     ]
  48     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  49       "-Dlv2dir=${placeholder "out"}/lib/lv2"
  50     ];
  51
  52   passthru = {
  53     tests = {
  54       inherit pipewire;
  55     };
  56     updateScript = gitUpdater {
  57       # No nicer place to find latest release.
  58       url = "https://gitlab.com/lv2/lv2.git";
  59       rev-prefix = "v";
  60     };
  61   };
  62
  63   meta = with lib; {
  64     homepage = "https://lv2plug.in";
  65     description = "Plugin standard for audio systems";
  66     mainProgram = "lv2_validate";
  67     license = licenses.mit;
  68     maintainers = [ ];
  69     platforms = platforms.unix;
  70   };
  71 }