pkgs/by-name/ma/marble-shell-theme/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchFromGitHub,
   5   python3,
   6   colors ? [ "all" ], # Default to install all available colors
   7   additionalInstallationTweaks ? [ ], # Additional installation tweaks
   8 }:
   9 assert lib.assertMsg (colors != [ ]) "The `colors` list can not be empty";
  10 stdenvNoCC.mkDerivation (finalAttrs: {
  11   pname = "marble-shell-theme";
  12   version = "46.2.3";
  13
  14   src = fetchFromGitHub {
  15     owner = "imarkoff";
  16     repo = "Marble-shell-theme";
  17     rev = "5971b15d8115c60c3a16b1d219ecffd2cfcdb323";
  18     hash = "sha256-TX6BSS29EAi2PjL1fMvEKD12RjB9xrfqPSQsJJrUcJg=";
  19   };
  20
  21   nativeBuildInputs = [ python3 ];
  22
  23   patchPhase = ''
  24     runHook prePatch
  25     substituteInPlace scripts/config.py \
  26       --replace-fail "~/.themes" ".themes"
  27     runHook postPatch
  28   '';
  29
  30   installPhase = ''
  31     runHook preInstall
  32     mkdir -p $out/share/themes
  33     python install.py ${
  34       lib.escapeShellArgs (map (color: "--${color}") colors)
  35     } ${lib.escapeShellArgs additionalInstallationTweaks}
  36     cp -r .themes/* $out/share/themes/
  37     runHook postInstall
  38   '';
  39
  40   meta = {
  41     description = "Shell theme for GNOME DE";
  42     license = lib.licenses.gpl3Plus;
  43     platforms = lib.platforms.linux;
  44     homepage = "https://github.com/imarkoff/Marble-shell-theme";
  45     changelog = "https://github.com/imarkoff/Marble-shell-theme/releases/tag/${finalAttrs.version}";
  46     maintainers = with lib.maintainers; [ aucub ];
  47   };
  48 })