pkgs/by-name/me/mesa-demos/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   libglut,
   6   libGL,
   7   libGLU,
   8   libX11,
   9   libXext,
  10   libgbm,
  11   mesa,
  12   meson,
  13   ninja,
  14   pkg-config,
  15   wayland,
  16   wayland-scanner,
  17   wayland-protocols,
  18   vulkan-loader,
  19   libxkbcommon,
  20   libdecor,
  21   glslang,
  22 }:
  23
  24 stdenv.mkDerivation rec {
  25   pname = "mesa-demos";
  26   version = "9.0.0";
  27
  28   src = fetchurl {
  29     url = "https://archive.mesa3d.org/demos/${pname}-${version}.tar.xz";
  30     sha256 = "sha256-MEaj0mp7BRr3690lel8jv+sWDK1u2VIynN/x6fHtSWs=";
  31   };
  32
  33   depsBuildBuild = [
  34     pkg-config
  35   ];
  36
  37   nativeBuildInputs = [
  38     meson
  39     ninja
  40     pkg-config
  41     wayland-scanner
  42     glslang
  43   ];
  44
  45   buildInputs = [
  46     libglut
  47     libX11
  48     libXext
  49     libGL
  50     libGLU
  51     libgbm
  52     wayland
  53     wayland-protocols
  54     vulkan-loader
  55     libxkbcommon
  56     libdecor
  57   ];
  58
  59   mesonFlags = [
  60     "-Degl=${if stdenv.hostPlatform.isDarwin then "disabled" else "auto"}"
  61     (lib.mesonEnable "libdrm" (stdenv.hostPlatform.isLinux))
  62     (lib.mesonEnable "osmesa" false)
  63     (lib.mesonEnable "wayland" (lib.meta.availableOn stdenv.hostPlatform wayland))
  64   ];
  65
  66   meta = with lib; {
  67     inherit (mesa.meta) homepage platforms;
  68     description = "Collection of demos and test programs for OpenGL and Mesa";
  69     license = licenses.mit;
  70     maintainers = with maintainers; [ andersk ];
  71   };
  72 }