pkgs/by-name/mf/mfc465cnlpr/package.nix

   1 { stdenv
   2 , lib
   3 , fetchurl
   4 , dpkg
   5 , makeWrapper
   6 , coreutils
   7 , file
   8 , gawk
   9 , ghostscript
  10 , gnused
  11 , pkgsi686Linux
  12 }:
  13
  14 stdenv.mkDerivation rec {
  15   pname = "mfc465cnlpr";
  16   version = "1.0.1-1";
  17
  18   src = fetchurl {
  19     url = "https://download.brother.com/welcome/dlf006132/${pname}-${version}.i386.deb";
  20     sha256 = "cfe0289510bf36bee6014286ea78b1ebc6bbb948dbfd3aee02f0664a7743f99b";
  21   };
  22
  23   unpackPhase = ''
  24     dpkg-deb -x $src $out
  25   '';
  26
  27   nativeBuildInputs = [
  28     dpkg
  29     makeWrapper
  30   ];
  31
  32   dontBuild = true;
  33
  34   installPhase = ''
  35     dir=$out/usr/local/Brother/Printer/mfc465cn
  36     patchelf --set-interpreter ${pkgsi686Linux.glibc.out}/lib/ld-linux.so.2 $dir/lpd/brmfc465cnfilter
  37     wrapProgram $dir/inf/setupPrintcapij \
  38       --prefix PATH : ${lib.makeBinPath [
  39         coreutils
  40       ]}
  41     substituteInPlace $dir/lpd/filtermfc465cn \
  42       --replace "BR_PRT_PATH=" "BR_PRT_PATH=\"$dir/\" #"
  43     wrapProgram $dir/lpd/filtermfc465cn \
  44       --prefix PATH : ${lib.makeBinPath [
  45         coreutils
  46         file
  47         ghostscript
  48         gnused
  49       ]}
  50     substituteInPlace $dir/lpd/psconvertij2 \
  51       --replace '`which gs`' "${ghostscript}/bin/gs"
  52     wrapProgram $dir/lpd/psconvertij2 \
  53       --prefix PATH : ${lib.makeBinPath [
  54         gnused
  55         gawk
  56       ]}
  57     chmod -R a+w $dir/inf/
  58   '';
  59
  60   meta = with lib; {
  61     description = "Brother MFC-465CN LPR printer driver";
  62     homepage = "http://www.brother.com/";
  63     license = licenses.unfree;
  64     maintainers = with maintainers; [ phrogg ];
  65     platforms = [ "i686-linux" "x86_64-linux" ];
  66   };
  67 }