pkgs/by-name/mf/mfc5890cnlpr/package.nix

   1 { stdenv
   2 , a2ps
   3 , lib
   4 , fetchurl
   5 , dpkg
   6 , makeWrapper
   7 , coreutils
   8 , file
   9 , gawk
  10 , ghostscript
  11 , gnused
  12 , pkgsi686Linux
  13 }:
  14
  15 stdenv.mkDerivation rec {
  16   pname = "mfc5890cnlpr";
  17   version = "1.1.2-2";
  18
  19   src = fetchurl {
  20     url = "https://download.brother.com/welcome/dlf006168/${pname}-${version}.i386.deb";
  21     sha256 = "119h3s1p9pv83mrfv6cmxpc0v33xf8c9nw5clj9yafv3aizxy6dp";
  22   };
  23
  24   unpackPhase = ''
  25     dpkg-deb -x $src $out
  26   '';
  27
  28   nativeBuildInputs = [
  29     dpkg
  30     makeWrapper
  31   ];
  32
  33   dontBuild = true;
  34
  35   installPhase = ''
  36     dir=$out/usr/local/Brother/Printer/mfc5890cn
  37
  38     patchelf --set-interpreter ${pkgsi686Linux.glibc.out}/lib/ld-linux.so.2 $dir/lpd/brmfc5890cnfilter
  39
  40     wrapProgram $dir/inf/setupPrintcapij \
  41       --prefix PATH : ${lib.makeBinPath [
  42         coreutils
  43       ]}
  44
  45     substituteInPlace $dir/lpd/filtermfc5890cn \
  46       --replace "/usr/" "$out/usr/"
  47
  48     wrapProgram $dir/lpd/filtermfc5890cn \
  49       --prefix PATH : ${lib.makeBinPath [
  50         a2ps
  51         coreutils
  52         file
  53         ghostscript
  54         gnused
  55       ]}
  56
  57     substituteInPlace $dir/lpd/psconvertij2 \
  58       --replace '`which gs`' "${ghostscript}/bin/gs"
  59
  60     wrapProgram $dir/lpd/psconvertij2 \
  61       --prefix PATH : ${lib.makeBinPath [
  62         gnused
  63         gawk
  64       ]}
  65   '';
  66
  67   meta = with lib; {
  68     description = "Brother MFC-5890CN LPR printer driver";
  69     homepage = "http://www.brother.com/";
  70     sourceProvenance = with sourceTypes; [ binaryNativeCode ];
  71     license = licenses.unfree;
  72     maintainers = with maintainers; [ martinramm ];
  73     platforms = [ "i686-linux" "x86_64-linux" ];
  74   };
  75 }