pkgs/by-name/mi/minilibx/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , installShellFiles
   5 , libX11
   6 , libXext
   7 , unstableGitUpdater
   8 }:
   9
  10 stdenv.mkDerivation {
  11   pname = "minilibx";
  12   version = "0-unstable-2021-10-30";
  13
  14   src = fetchFromGitHub {
  15     owner = "42Paris";
  16     repo = "minilibx-linux";
  17     rev = "7dc53a411a7d4ae286c60c6229bd1e395b0efb82";
  18     hash = "sha256-aRYMpaPC7dC6EHmmXugvwcQnaizRCQZKFcQX0K2MLM4=";
  19   };
  20
  21   outputs = [ "out" "dev" "man" ];
  22
  23   nativeBuildInputs = [
  24     installShellFiles
  25   ];
  26
  27   buildInputs = [
  28     libX11
  29     libXext
  30   ];
  31
  32   dontConfigure = true;
  33
  34   makefile = "Makefile.mk";
  35
  36   makeFlags = [
  37     "CC=${stdenv.cc.targetPrefix}cc"
  38   ];
  39
  40   installPhase = ''
  41     runHook preInstall
  42
  43     mkdir -p $out/{include,lib}
  44     cp mlx*.h $out/include
  45     cp libmlx*.a $out/lib
  46     installManPage man/man*/*
  47
  48     runHook postInstall
  49   '';
  50
  51   passthru = {
  52     updateScript = unstableGitUpdater { };
  53   };
  54
  55   meta = with lib; {
  56     description = "Simple X-Window (X11R6) programming API in C";
  57     homepage = "https://github.com/42Paris/minilibx-linux";
  58     license = licenses.bsd2;
  59     maintainers = with maintainers; [ wegank ];
  60     platforms = platforms.unix;
  61   };
  62 }