pkgs/by-name/ml/mlflow-server/package.nix

   1 { python3Packages, writers }:
   2
   3 let
   4   py = python3Packages;
   5
   6   gunicornScript = writers.writePython3 "gunicornMlflow" { } ''
   7     import re
   8     import sys
   9     from gunicorn.app.wsgiapp import run
  10     if __name__ == '__main__':
  11         sys.argv[0] = re.sub(r'(-script\.pyw|\.exe)?$', ''', sys.argv[0])
  12         sys.exit(run())
  13   '';
  14 in
  15 py.toPythonApplication (
  16   py.mlflow.overridePythonAttrs (old: {
  17
  18     propagatedBuildInputs = old.dependencies ++ [
  19       py.boto3
  20       py.mysqlclient
  21     ];
  22
  23     postPatch =
  24       (old.postPatch or "")
  25       + ''
  26         cat mlflow/utils/process.py
  27
  28         substituteInPlace mlflow/utils/process.py --replace-fail \
  29           "process = subprocess.Popen(" \
  30           "cmd[0]='${gunicornScript}'; process = subprocess.Popen("
  31       '';
  32
  33     postInstall = ''
  34       gpath=$out/bin/gunicornMlflow
  35       cp ${gunicornScript} $gpath
  36       chmod 555 $gpath
  37     '';
  38   })
  39 )