pkgs/by-name/ni/nice-dcv-client/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   glib,
   6   libX11,
   7   gst_all_1,
   8   libepoxy,
   9   pango,
  10   cairo,
  11   gdk-pixbuf,
  12   e2fsprogs,
  13   libkrb5,
  14   libva,
  15   openssl,
  16   pcsclite,
  17   gtk3,
  18   libselinux,
  19   libxml2,
  20   libffi,
  21   python3Packages,
  22   cpio,
  23   autoPatchelfHook,
  24   wrapGAppsHook3,
  25 }:
  26
  27 stdenv.mkDerivation rec {
  28   pname = "nice-dcv-client";
  29   version = "2021.2.3797-1";
  30   src = fetchurl {
  31     url = "https://d1uj6qtbmh3dt5.cloudfront.net/2021.2/Clients/nice-dcv-viewer-${version}.el8.x86_64.rpm";
  32     sha256 = "sha256-iLz25SB5v7ghkAZOMGPmpNaPihd8ikzCQS//r1xBNRU=";
  33   };
  34
  35   nativeBuildInputs = [
  36     autoPatchelfHook
  37     wrapGAppsHook3
  38     python3Packages.rpm
  39   ];
  40   unpackPhase = ''
  41     rpm2cpio $src | ${cpio}/bin/cpio -idm
  42   '';
  43
  44   buildInputs = [
  45     libselinux
  46     libkrb5
  47     libxml2
  48     libva
  49     e2fsprogs
  50     libX11
  51     openssl
  52     pcsclite
  53     gtk3
  54     cairo
  55     libepoxy
  56     pango
  57     gdk-pixbuf
  58     gst_all_1.gstreamer
  59     gst_all_1.gst-plugins-base
  60   ];
  61
  62   installPhase = ''
  63     mkdir -p $out/bin/
  64     mkdir -p $out/lib64/
  65     mv usr/bin/dcvviewer $out/bin/dcvviewer
  66     mv usr/lib64/* $out/lib64/
  67     mkdir -p $out/libexec/dcvviewer
  68     mv usr/libexec/dcvviewer/dcvviewer $out/libexec/dcvviewer/dcvviewer
  69     patchelf \
  70       --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
  71       $out/libexec/dcvviewer/dcvviewer
  72     # Fix the wrapper script to have the right basedir.
  73     sed -i "s#basedir=/usr#basedir=$out#" $out/bin/dcvviewer
  74     mv usr/share $out/
  75
  76     ${glib.dev}/bin/glib-compile-schemas $out/share/glib-2.0/schemas
  77
  78     # we already ship libffi.so.7
  79     ln -s ${lib.getLib libffi}/lib/libffi.so $out/lib64/libffi.so.6
  80   '';
  81
  82   meta = with lib; {
  83     description = "High-performance remote display protocol";
  84     homepage = "https://aws.amazon.com/hpc/dcv/";
  85     sourceProvenance = with sourceTypes; [ binaryNativeCode ];
  86     license = licenses.unfree;
  87     platforms = [ "x86_64-linux" ];
  88     maintainers = with maintainers; [ rmcgibbo ];
  89   };
  90 }